;;; -*- Mode: tdl; Coding: utf-8; -*-

;;
;; even though we originally made sure all tokens had a fully specified +TNT
;; value, intervening rules could have `leaked' PoS information.  if so, once
;; again, fully annul the +TNT value.
;;

tnt_default_tmr := one_one_tmt &
[ +INPUT  < [ +FORM #form, +TRAIT #trait,
              +TNT [ +TAGS < anti_string, ... > ] ] >,
  +OUTPUT < [ +FORM #form, +TRAIT #trait,
              +TNT null_tnt ] > ].

tnt_recurse_tmr := token_mapping_rule &
[ +INPUT  < [ +FORM #form, +TRAIT anti_trait,
              +IDS #ids, +FROM #from, +TO #to,
              +TNT [ +TAGS < #tag . #tags & ne-list >,
                     +PRBS < #prb . #prbs & ne-list > ] ] > ,
  +OUTPUT < [ +FORM #form, +TRAIT native_trait,
              +IDS #ids, +FROM #from, +TO #to,
              +TNT [ +TAGS < #tag >, +PRBS < #prb > ] ],
            [ +FORM #form, +TRAIT anti_trait,
              +IDS #ids, +FROM #from, +TO #to,
              +TNT [ +TAGS #tags, +PRBS #prbs ] ] > ,
  +POSITION "O1@I1, O2@I1" ].

tnt_terminate_tmr := token_mapping_rule &
[ +INPUT  < [ +FORM #form, +TRAIT anti_trait,
              +IDS #ids, +FROM #from, +TO #to,
              +TNT [ +TAGS < #tag >, +PRBS < #prb > ] ] > ,
  +OUTPUT < [ +FORM #form, +TRAIT native_trait,
              +IDS #ids, +FROM #from, +TO #to,
              +TNT [ +TAGS < #tag >, +PRBS < #prb > ] ] > ,
  +POSITION "O1@I1" ].