;;; -*- Mode: tdl; Coding: utf-8; -*-

; CSY 6-1-2020 - removed (not needed for Singlish) so that 
;                the num is always underspec if the noun is in it's original form
n_sg_ilr := never_unify_rule.


; CSY 29-12-2020 for nouns in the base form that are unspecified for number
;     5-1-2020 added in MIN nonpro so the rule cannot apply to pronouns?
;              test: not sure if that is necessary
; 2-3-2021 - find a way to add nonc-hm into the input such that proper names cannot undergo this
; 10-3-2021 - removed MINORS.MIN nonpro_rel and the nonc-hm
n_singlish_ilr := n_singlish_inflrule &
"""
Underspec noun
<ex>cat (no det)
"""
[ ND-AFF -,
  ORTH #stem,
  DTR  [ ORTH #stem ],
  SYNSEM count_noun_synsem & [ LOCAL singlish_count_noun & [ AGR.PNG norm-png ] ],
  RNAME lncn ].

; CSY - 2-11-2020 changed SYNSEM from bse_or_non3sg_verb 
v_fin-bse_ilr := v_n3s-bse_inflrule &
"""
base form verb for all including 3sg      
<ex> He admire...
"""
[ ND-AFF -,
  ORTH #stem,
  DTR  [ ORTH #stem ],
  SYNSEM.LOCAL bse_or_fin_verb,
  RNAME lvns ].

; remove this non third singular inflr to avoid overgeneration
v_n3s-bse_ilr := never_unify_rule.

; 8-7-2021 - added DIALECT us into this so that the specifically Singlish words will not
; take the 3s -s suffix eg. *he sabos the plan.
; #temporary. Judgement may differ for among speakers
v_3s-fin_olr :=
%suffix (!s !ss) (!ss !ssses) (ss sses) (!ty !ties) (ch ches) (sh shes) (x xes) (z zes)
"""
Third-singular present finie verb      
<ex>admires                    
"""
v_3s-fin_inflrule &
[ ND-AFF +,
  SYNSEM.LOCAL third_sg_fin_verb,
  DIALECT us,
  RNAME lvsg ].