;;; -*- Mode: TDL; Coding: utf-8 -*- 

;;; HAG (Hausa Grammar)
;;; Author: Berthold Crysmann 
;;; 2009


subj-extra := 
	      extracted-subj-phrase.

head-comp := head-comp-phrase & 
	     [HEAD-DTR [KEY-ARG +,
			SYNSEM.LOCAL.CAT.VAL.COMPS <[LOCAL.CAT.HEAD.CASE npro-case],...>]].


head-procomp := head-comp-phrase & 
		[HEAD-DTR word-or-lexrule & 
			  [KEY-ARG +,
			   SYNSEM.LOCAL.CAT [HEAD +vp,
					     VAL.COMPS <[LOCAL.CAT.HEAD noun &
									[CASE pro-case]],...>]],
		 NON-HEAD-DTR word-or-lexrule].


subj-head := subj-head-phrase &
	     [SYNSEM [LOCAL [CAT.HEAD.VFORM indep]],
	      HEAD-DTR.KEY-ARG +,
	      NON-HEAD-DTR.SYNSEM.NON-LOCAL.QUE 0-dlist].

head-adj_i := head-adj-phrase & [C-CONT.HCONS <! !>,
				 SYNSEM.LOCAL.CONT.HOOK [LTOP #t,
						       INDEX #i,
						       XARG #x],
			       HEAD-DTR [KEY-ARG -,
					 SYNSEM [MODIFIABLE na-or-+,
						 LOCAL.CONT.HOOK [INDEX #i,
								  LTOP #t]]],
			       NON-HEAD-DTR [KEY-ARG +,
					     SYNSEM.LOCAL.CONT.HOOK [INDEX #x, 
								    LTOP #t]]].

n-rel := head-rel-phrase.

spr-head := spec-head-phrase & [NON-HEAD-DTR.KEY-ARG +].

bare-np := bare-np-phrase &
	   [SYNSEM [MODIFIABLE -,
		    LOCAL [CAT [HEAD noun]]],
	    HEAD-DTR.SYNSEM.LOCAL.CAT.VAL.SPR <unexpressed>].


;;; Need to add relation for subject
null-subj := basic-head-opt-subj-phrase &
	     [SYNSEM.LOCAL [CAT.HEAD.VFORM indep] ].

;;; Need to differentiate between semantically potent 
;;; and semantically inert relative tam

filler-head := filler-head-phrase &
	       head-compositional & 
	       [SYNSEM.LOCAL.CAT.VAL [SUBJ <>,
				      SPEC <>],
		NON-HEAD-DTR.KEY-ARG -, 
		HEAD-DTR [KEY-ARG +,
			  SYNSEM.LOCAL [CAT [HEAD [VFORM fin],
					     VAL [SUBJ <>,
						  COMPS <>,
						  SPR <>,
						  SPEC <>]],
					CONT.HOOK.INDEX [_REL na-or-+]]]].

relfill-head :=
		  rel-filler-head-phrase &
		  head-compositional & 
		  [SYNSEM.LOCAL.CAT.VAL [SUBJ <>,
					 SPEC <>],
		   NON-HEAD-DTR.KEY-ARG -, 
		   HEAD-DTR [KEY-ARG +,
			     SYNSEM.LOCAL [CAT [HEAD [VFORM fin],
						VAL [SUBJ <>,
						  COMPS <>,
						  SPR <>,
						  SPEC <>]],
					   CONT.HOOK.INDEX [_REL na-or-+]]]].


;;; Multi-word units (total reduplication)


n-pl-reduplication :=
		     total-reduplication-phrase &
		     [MORPH.COMPLETE +,
		      C-CONT [RELS <! !>,
			      HCONS <! !>,
			      HOOK #hook],
		      ARGS < [MORPH [MCLASS n-pl-12, 
				     COMPLETE na],
			      SYNSEM.LOCAL [CAT.HEAD noun, 
					    AGR [PNG.PN pl],
					    CONT.HOOK.INDEX.INSTLOC "undef"]], 
			     [MORPH [COMPLETE -,
				     MCLASS n-pl-12],
			      SYNSEM.LOCAL [CAT.HEAD noun, 
					    CONT.HOOK #hook,
					    AGR [PNG.PN pl]]] 
			      >].