;;; Hey, emacs (1), this is -*- mode:tdl; Coding: utf-8; -*-
;;; 
;;; Montserrat Marimon
;;; IULA - UPF
;;;
;;; lrtypes.tdl: (non-inflectional) lexical rule types for the SRG


; --- 1. LR types for valence alternation
basic-valence-alt-lex-rule := const-ltol-rule &
  [ SYNSEM [ MODIFIED #modified,
             PUNCT #punct,
             LOCAL [ COORD #coord,
                     COORD-REL #coord-rel,
                     COORD-STRAT #coord-strat,
                     CAT [ HEAD [ MOD #mod,
                                  PRD #prd,
                                  TAM #tam,
                                  CASE #case,
                                  KEYS #keys ], 
                           VAL [ SPEC #spec,
                                 SPR #spr ] ], 
                     CTXT #ctxt ] ],
    DTR [ SYNSEM [ MODIFIED #modified,
                   PUNCT #punct & [ RPUNCT no_punct ],
                   LOCAL [ COORD #coord,
                           COORD-REL #coord-rel,
                           COORD-STRAT #coord-strat,
                           CAT [ HEAD [ MOD #mod,
                                        PRD #prd,
                                        TAM #tam,
                                        CASE #case,
                                        KEYS #keys ], 
                                 VAL [ SPEC #spec,
                                       SPR #spr ] ], 
                           CTXT #ctxt ] ] ],
    C-CONT.RELS <! !> ].

valence-alt-lex-rule := basic-valence-alt-lex-rule &
  [ SYNSEM [ LOCAL [ CAT.HEAD #head,
                     CONT #cont ],
             NON-LOCAL #nonloc,
             LKEYS #lkeys ],
    DTR [ INFLECTED -,
          SYNSEM [ LOCAL [ CAT.HEAD #head,
                           CONT #cont ],
                   NON-LOCAL #nonloc,
                   LKEYS #lkeys ],
          ARG-ST #arg-st ],
    ARG-ST #arg-st ].


; --- 1.1. LR type for permutation of complements
comps_perm-lex-rule := valence-alt-lex-rule & 
  [ ALTS [ CAUS -,
           PERM -,
           PASS -,
           SYMM -,
           VFALT -,
           IMPERS - ],
    SYNSEM.LOCAL [ AGR #agr,
                   CAT.VAL [ SUBJ #subj,
                             COMPS  < [ OPT -,
                                        CLTCZD #cltczd,
				        LOCAL #local-comp2,
                                        NON-LOCAL #nlocal-comp2 ],
                                      [ OPT -,
                                        CLTCZD #cltczd,
				        LOCAL #local-comp1,
                                        NON-LOCAL #nlocal-comp1 ] >,
                             CLTS #clts ] ],
    DTR [ ALTS [ PERM + ],
          SYNSEM.LOCAL [ AGR #agr,
                         CAT.VAL [ SUBJ #subj,
                                   COMPS < [ CLTCZD #cltczd,
				             LOCAL #local-comp1,
                                             NON-LOCAL #nlocal-comp1 ],
                                           [ CLTCZD #cltczd,
				             LOCAL #local-comp2,
                                             NON-LOCAL #nlocal-comp2 ] >,
                                   CLTS #clts ] ] ] ].


; --- 1.2. LR types for causative alternation
basic-decausative-lex-rule := basic-valence-alt-lex-rule & 
  [ ALTS [ CAUS -,
           PERM -,
           PASS -,
           SYMM -,
           VFALT -,
           IMPERS #impers ],
    SYNSEM [ LOCAL [ CAT [  MC #mc,
                            HEAD [ MOD #mod,
                                   PRD #prd,
                                   TAM #tam, 
                                   CASE #case,
                                   VOICE #voice,
                                   VFORM #vform,
                                   KEYS #keys ] ],
                     CONT [ HOOK [ LTOP #ltop,
                                   XARG #objind,
                                   INDEX #index ],
			    RELS.LIST.FIRST #keyrel,
			    HCONS #hcons ] ],
             NON-LOCAL #nonloc,
             LKEYS.KEYREL #keyrel & [ PRED #pred,
                                      LBL #ltop,
                                      ARG0 #index,
                                      ARG2 #objind ] ],
    DTR [ INFLECTED -,
          ALTS.IMPERS #impers,
          SYNSEM [ LOCAL [ CAT [  MC #mc,
                                  HEAD [ MOD #mod,
                                         PRD #prd,
                                         TAM #tam, 
                                         CASE #case,
                                         VOICE #voice,
                                         VFORM #vform,
                                         KEYS #keys ] ],
                           CONT [ HOOK [ LTOP #ltop,
                                         INDEX #index ],
			          HCONS #hcons ] ],
                   NON-LOCAL #nonloc,
                   LKEYS.KEYREL.PRED #pred ] ] ].


; --- 1.2.1. LR type for causative alternation without "se"
; e.g. Seat aumentó las ventas -> las ventas aumentaron
int_decaus-lex-rule := basic-decausative-lex-rule & 
  [ SYNSEM v_intrans_synsem & 
           [ LOCAL [ AGR #agr,
                     CAT.VAL [ SUBJ < [ LOCAL np_nom_local & 
                                                [ AGR #agr,
                                                  CONT #objcont & [ HOOK.INDEX #objind ] ], 
                                          NON-LOCAL #ononloc & [ SLASH 0-dlist ] ] >,
                               COMPS < >,
                               CLTS #clts ] ] ],
    DTR [ ALTS [ CAUS -,
                 PASS + ],
          SYNSEM trans-caus-int-verb-synsem &
                 [ LOCAL [ AGR #agr,
                           CAT.VAL [ COMPS < [ LOCAL.CONT #objcont & [ HOOK.INDEX #objind ],
                                               NON-LOCAL #ononloc ] >,
                                     CLTS #clts & < > ] ] ] ] ].


; --- 1.2.2. LR type for causative alternation with "se"
; e.g. Juan rompió la mesa (causative) -> la mesa se rompió (unaccusative)
decaus-lex-rule := basic-decausative-lex-rule & 
  [ SYNSEM.LOCAL [ AGR #objind,
                   CAT.VAL [ SUBJ < canonical-synsem &
                                    [ LOCAL np_nom_local & 
                                            [ CONT #objcont & [ HOOK.INDEX #objind ] ], 
                                      NON-LOCAL #ononloc & [ SLASH 0-dlist ] ] >,
                             COMPS #comps,
                             CLTS < [ OPT -,
                                      LOCAL [ CAT.HEAD affix & [ CASE rflx ],
                                              CONT.HOOK.INDEX ref-ind & #objind ] ] > ] ],
    DTR [ ALTS.CAUS +,
          SYNSEM v_trans_np_synsem &
                 [ LOCAL [ AGR #objind,
                           CAT.VAL [ SUBJ < synsem-min & 
                                            [ LOCAL [ CAT.HEAD noun,
                                                      CONT [ HOOK.INDEX ref-ind,
                                                             RELS.LIST < noun-relation> ] ] ] >,
                                     COMPS < [ LOCAL.CONT #objcont & [ HOOK.INDEX #objind ],
                                               NON-LOCAL #ononloc ]
                                             . #comps >,
                                     CLTS < > ] ] ] ] ].

1valent_decaus-lex-rule := decaus-lex-rule & 
  [ DTR.SYNSEM.LOCAL.CAT.VAL.COMPS < synsem > ].

2valent_decaus-lex-rule := decaus-lex-rule & 
  [ DTR.SYNSEM.LOCAL.CAT.VAL.COMPS < synsem , [ LOCAL lcomp_local ] > ].

3valent_decaus-lex-rule := decaus-lex-rule & 
  [ SYNSEM.LOCAL.CONT.RELS.LIST.FIRST.ARG3 #arg3,
    DTR.SYNSEM.LOCAL [ CAT.VAL.COMPS < synsem , [ LOCAL.CAT.HEAD.KEYS.KEY selected_rel,
                                                  NON-LOCAL [ SLASH 0-dlist,
                                                              REL 0-dlist,
                                                              QUE 0-dlist ] ] > ,
                       CONT.RELS.LIST.FIRST.ARG3 #arg3 ] ].


; --- 1.3. LR types for symmetric predicates
basic-sym_pred-lex-rule := basic-valence-alt-lex-rule & 
  [ ALTS [ CAUS -,
           PERM -,
           SYMM - ],
    SYNSEM [ LOCAL [ CAT [ MC #mc,
                           VAL.CLTS #clts ],
                     CONT [ HOOK [ LTOP #ltop,
                                   INDEX #index ],
			    RELS.LIST.FIRST #keyrel,
			    HCONS #hcons ] ],
             NON-LOCAL #nonlocal,
             LKEYS.KEYREL #keyrel & [ PRED #pred,
                                      LBL #ltop,
                                      ARG0 #index ] ],
    DTR [ INFLECTED -,
          ALTS.SYMM +,
          SYNSEM [ LOCAL [ CAT [ MC #mc,
                                 HEAD.CLIT none ,
                                 VAL.CLTS #clts ],
                           CONT [ HOOK [ LTOP #ltop,
                                         INDEX #index ],
			          HCONS #hcons ] ],
                   NON-LOCAL #nonlocal,
                   LKEYS.KEYREL.PRED #pred ] ] ].

; --- 1.3.1. symmetric verbs taking marked NP / plural (or coord.) subject 
sym_pred_pl_subj-lex-rule := basic-sym_pred-lex-rule & 
  [ ALTS [ PASS -,
           IMPERS - ],
    SYNSEM [ LOCAL [ AGR #agr,
                     CAT.VAL [ SUBJ < [ LOCAL np_nom_local & 
                                              [ AGR #agr & [ PNG.PN plur ] ],
                                        NON-LOCAL #nlocal ] >,
                               COMPS #rest ],
                     CONT.HOOK.XARG #agr ],
             LKEYS.KEYREL.ARG1 #agr ],
    DTR.SYNSEM.LOCAL.CAT.VAL.COMPS < [ LOCAL mrkd_np_local,
                                       NON-LOCAL #nlocal & [ SLASH 0-dlist,
                                                             REL 0-dlist,
                                                             QUE 0-dlist ] ]
                                     . #rest > ].

; e.g. conversar (to chat) (A conversa con B/A y B conversan)
intr_sym_pred_pl_subj-lex-rule := sym_pred_pl_subj-lex-rule &
  [ ALTS.VFALT -,
    SYNSEM v_intrans_synsem & 
           [ LOCAL.CAT.VAL.COMPS < > ],
    DTR.SYNSEM v_intr_mrkd_np_sym_synsem & 
               [ LOCAL.CAT.VAL.COMPS < synsem > ] ].

; e.g. A acordó con B no hablar/que no hablarían -> A y B acordaron no hablar/que no hablarían
trans_sym_pred_pl_subj-lex-rule := sym_pred_pl_subj-lex-rule &
  [ ALTS.VFALT #vfalt,
    SYNSEM v_trans_cp_prop-or-ques_fin_synsem &
           [ LOCAL.CAT.VAL.COMPS < [ NON-LOCAL [ SLASH 0-dlist,
                                                 REL 0-dlist,
                                                 QUE 0-dlist ] ] >,
             LKEYS.KEYREL.ARG2 #arg2 ],
    DTR [ ALTS.VFALT #vfalt,
          SYNSEM v_sym_trans_cp_prop_fin_mrkd_np_synsem &
                 [ LKEYS.KEYREL.ARG2 #arg2 ] ] ].

; --- 1.3.2. transitive symmetric verbs taking DO and marked NP / plural (or coord.) DO
; e.g. polarización que confrontará [la docencia a/con la investigación/la docencia y la investigación]
sym_pred_pl_do-lex-rule := basic-sym_pred-lex-rule & 
  [ ALTS [ PASS +,
           VFALT -,
           IMPERS + ],
    SYNSEM v_trans_np_synsem &
           [ LOCAL [ AGR #agr,
                     CAT.VAL [ SUBJ #subj,
                               COMPS < [ OPT -,
                                         LOCAL np_acc_local & 
                                               [ CONT.HOOK.INDEX ref-ind & #arg2 & [ PNG.PN plur ] ],
                                         NON-LOCAL #nlocal ] > ],
                     CONT.HOOK.XARG #agr ],
             LKEYS.KEYREL.ARG2 #arg2 ],
    DTR.SYNSEM v_trans_np_mrkd_np_sym_synsem &
               [ LOCAL [ AGR #agr,
                         CAT.VAL [ SUBJ #subj,
                                   COMPS < [ LOCAL np_acc_local,
                                             NON-LOCAL #nlocal & [ SLASH 0-dlist,
                                                                   REL 0-dlist,
                                                                   QUE 0-dlist ] ], 
                                           [ LOCAL mrkd_np_local ] > ] ] ] ].


; --- 1.4. LR types for constructions with "se"
basic-se-construct-lex-rule := basic-valence-alt-lex-rule &
  [ ALTS [ CAUS -,
           PASS -,
           SYMM -,
           VFALT - ],
    SYNSEM [ LOCAL [ CAT [ HEAD [ AUX #aux,
                                  VFORM #vform,
                                  TAM #tam,
                                  PRD #prd,
                                  KEYS #keys,
                                  MOD #mod ] ],
                     CONT #cont ],
            LKEYS #lkeys,
            NON-LOCAL #nonlocal ],
    DTR [ SYNSEM [ LOCAL [ CAT [ HEAD verb & 
                                      [ AUX #aux,
                                        VFORM #vform,
                                        TAM #tam,
                                        PRD #prd,
                                        KEYS #keys,
                                        MOD #mod ] ],
                           CONT #cont ],
                   LKEYS #lkeys,
                   NON-LOCAL #nonlocal ] ] ].

; --- 1.4.1. impersonal constructions with "se"
; - In this constructions the verb appears in 3gl and the complement is the arg2, (this is generally an 
; animate entity singular o plural (e.g. a los hijos no se les escoge), or inanimate with verbs taking 
; marked NP (e.g. de las drogas se depende fácilmente))
; - They co-occur with: transitive and ditransitive verbs where the DO may or may not be introduced by "a" 
; (e.g. se reclutó (a los) soldados, se envió un regalo a los novios), verbs taking marked NPs (e.g. se 
; cree en milagros), perception verbs (e.g. se ve caer las gotas de agua), causative verbs (e.g. se 
; hizo/dejó a Núria asistir a la reunión), verbos taking reduced clauses (e.g. se considera invalidas 
; las pruebas) and unaccusative verbs (e.g. siempre se llega tarde)
impersonal-se-lex-rule := basic-se-construct-lex-rule &
  [ ALTS.IMPERS -,
    SYNSEM.LOCAL [ AGR #agr & [ PNG.PN 3sg ],
                   CAT [ HEAD [ VOICE #voice,
                                INV #inv,
                                CLIT #case ], 
                         VAL [ SUBJ #subj & < unexpressed >,
                               COMPS #comps,
                               CLTS < #clt & affix-synsem &
                                      [ LOCAL.CAT.HEAD.CASE #case & none ] 
                                      . #clts > ] ] ],
    DTR [ INFLECTED -,
          ALTS.IMPERS +,
          SYNSEM.LOCAL [ AGR #agr,
                         CAT [ HEAD [ VOICE #voice,
                                      INV #inv ],
                               VAL [ SUBJ #subj, 
                                     COMPS #comps,
                                     CLTS #clts ] ] ],
          ARG-ST #arg-st ],
    ARG-ST < #arg-st . #clt >,
    C-CONT.HCONS <! !> ].


; a)- unacussative verbs (e.g. siempre se llega tarde)
v_unacc-impersonal-se-lex-rule := impersonal-se-lex-rule &
  [ ALTS.PERM -,
    DTR [ SYNSEM unacc_lt & 
                 [ LOCAL.CAT.VAL.CLTS < > ] ] ].

; b)- intransitive verbs taking marked NP complements (e.g. se cree en milagros, se invierte en bolsa)
v_intr-impersonal-se-lex-rule := impersonal-se-lex-rule &
  [ ALTS.PERM -,
    DTR.SYNSEM.LOCAL.CAT.VAL.COMPS < [ LOCAL mrkd_np_local ],... > ].


; - to avoid overgeneration with passives, complements are specified to be plural
; c)- transitive verbs (e.g. se reclutó (a los) soldados, se ve caer las gotas de agua,... )
v_trans-impersonal-se-lex-rule := impersonal-se-lex-rule &
  [ ALTS.PERM +,
    DTR.SYNSEM.LOCAL [ CAT.VAL.COMPS < [ LOCAL np_acc_local & [ AGR.PNG.PN 3pl ] ],... > ] ].


; --- 1.4.2. passive/medium constructions with "se"

basic-passive-se-lex-rule := basic-se-construct-lex-rule &
  [ ALTS [ IMPERS -,
           PERM #perm ],
    SYNSEM.LOCAL [ AGR.PNG.PN #pn,
                   CAT [ HEAD verb & 
                              [ AUX -,
                                VOICE passive,
                                VFORM #vform & fin,
                                TAM.MOOD #mood,
                                CLIT #case ], 
                         VAL.CLTS #clt & 
                                  < [ OPT -,
                                      LOCAL [ CAT.HEAD affix & [ CASE #case & none ],
                                              CONT.HOOK.INDEX ref-ind ] ] > ],
                   CONT.HOOK.INDEX.E.MOOD #mood ],
    DTR [ INFLECTED +,
          ALTS.PERM #perm,
          SYNSEM.LOCAL [ AGR.PNG.PN #pn & 3per,
                         CAT [ HEAD verb &
                                    [ AUX -,
                                      VOICE active,
                                      VFORM #vform ],
                               VAL [ SUBJ < [ LOCAL np_nom_local ] >,
                                     CLTS < > ] ] ],
          ARG-ST #arg-st ],
    ARG-ST < #arg-st . #clt > ].

v_transitive-passive-se-lex-rule := basic-passive-se-lex-rule & 
  [ SYNSEM.LOCAL.CAT.VAL.SUBJ < synsem &
                                [ OPT -,
                                  LOCAL.CONT #objcont & [ HOOK.INDEX #objind ],
                                  NON-LOCAL #ononloc & [ SLASH 0-dlist ] ] >,
    DTR.SYNSEM.LOCAL.CAT.VAL.COMPS < [ LOCAL.CONT #objcont & [ HOOK.INDEX #objind ],
                                       NON-LOCAL #ononloc ],... > ].


; -- passive constructions
; - tienen como sujeto gramatical el objeto nocional del verbo, este suele aparecer pospuesto, 
; y puede ser indeterminado (sin determinado, con determinantes indefinidos y numerales 
; (se quemaron los bosques para acabar con la plaga, se venden casas)). Cuando aparece antepuesto 
; es foco, y puede ser indeterminado.
; - a veces no concuerda el sujeto con el verbo, como con los SN plurales sin det. (se vende pisos) 
; pero deben concordar con SN determinados con art. definidos o demostrativos, cuando el suj. se 
; antepone, ... (pp. 1676)
; - pueden aparecer con todo tipo de verbos transitivos, ditransitivos y verbos que alternan 
; usos transitivos e intransitivos en los que en la oración transitiva con suj. explícito 
; correspondiente el CD de persona (anim) no va introducido por "a" (i.e. no lleva determinante 
; o este es indef. (e.g. se necesitan (unos/varios/muchos...) estudiantes)), verbos con complementos 
; oracionales (e.g. se cree que, se afirma que...), y verbos con objetos oracionales infinitivos 
; (e.g. se prohíbe fumar). 
; -- medium constructions
; - no muestran restricciones aspectuales
; - expresa una acción verbal que 'afecta' al sujeto gramatical
; - tienen como sujeto gramatical el objeto nocional del verbo, este suele aparecer antepuesto,  
; desempeñando la función de tema o tópico, tiene el rasgo determinado (aparece con art. 
; definidos, demostrativos, etc.), y es un ente generalmente inanimado, singular o plural 
; (en verano los bosques se queman fácilmente) o animado plural (los hijos no se escogen). 
; - con verbos transitivos cuyo sujeto nocional tiene el papel temático de agente y no puede especificarse  
; - con verbos con valor imperfectivo (i.e. presente o pretérito imperfecto).


; - to avoid overgeneration with causatives, this rule only applies to not causative verbs
; a)- transitive verbs (e.g. se necesitan (unos/varios/muchos...) estudiantes)
v_trans-passive-se-lex-rule := v_transitive-passive-se-lex-rule &
  [ SYNSEM.LOCAL [ AGR #ind,
                   CAT [ VAL [ SUBJ < [ LOCAL np_nom_local & 
                                              [ AGR #ind,
                                                CAT.HEAD.KEYS [ KEY nom_rel ],
                                                CONT.HOOK.INDEX ref-ind ] ] >,
                               COMPS #comps ] ] ],
    DTR [ ALTS.CAUS -,
          SYNSEM.LOCAL.CAT.VAL.COMPS < [ LOCAL np_acc_local ]. #comps > ] ].

; b)- verbs taking finite completive clauses (e.g. se cree que fue así, se afirma que...) and/or VPinf 
; (e.g. se prohíbe fumar)
v_trans_cp-passive-se-lex-rule := v_transitive-passive-se-lex-rule &
  [ SYNSEM.LOCAL [ AGR.PNG.PN 3sg,
                   CAT [ HEAD.INV +,
                         VAL [ SUBJ < [ LOCAL.CAT #cat ] >,
                               COMPS < > ] ] ],
    DTR.SYNSEM.LOCAL.CAT.VAL.COMPS < [ LOCAL v_local & 
                                             [ CAT #cat,
                                               CONT.HOOK.INDEX.SF prop ] ] > ].

; c)- ditransitive verbs (e.g. se le prometió ir/que irían)
v_ditrans-passive-se-lex-rule := basic-passive-se-lex-rule & 
  [ SYNSEM.LOCAL [ AGR.PNG.PN 3sg,
                   CAT [ HEAD.INV +,
                         VAL [ SUBJ < [ OPT -,
                                        LOCAL [ CAT #cat,
                                                CONT #objcont & [ HOOK.INDEX #objind ] ],
                                        NON-LOCAL #ononloc & [ SLASH 0-dlist ] ] >,
                               COMPS < #comp > ] ] ],
    DTR.SYNSEM.LOCAL.CAT.VAL.COMPS < #comp & [ LOCAL dative_local ],
                                     [ LOCAL v_local & 
                                             [ CAT #cat,
                                               CONT #objcont & [ HOOK.INDEX #objind & [ SF prop ] ] ],
                                       NON-LOCAL #ononloc ] > ].



; --- 1.5. LR types for finite clause /VPinf alternation

vfin_vinf-lex-rule := basic-lex-rule & phrase-or-lexrule &
  [ STEM #stem,
    INFLECTED #infl,
    ALTS [ SYMM -,
           CAUS #caus,
           PASS #pass,
           PERM #perm,
           IMPERS #impers ],
    SYNSEM [ MODIFIED #modified,
             PUNCT #punct,
             LOCAL [ COORD #coord,
                     COORD-REL #coord-rel,
                     COORD-STRAT #coord-strat,
                     AGR #agr,
                     CAT [ MC #mc,
                           HEAD #head,
                           VAL [ SPR #spr,
                                 SPEC #spec ] ],
                     CTXT #ctxt ],
             NON-LOCAL #nonloc ],
    DTR [ STEM #stem,
          INFLECTED #infl,
          ALTS [ CAUS #caus,
                 PASS #pass,
                 PERM #perm,
                 VFALT +,
                 IMPERS #impers ],
          SYNSEM [ MODIFIED #modified,
                   PUNCT #punct & [ RPUNCT no_punct ],
                   LOCAL [ COORD #coord,
                           COORD-REL #coord-rel,
                           COORD-STRAT #coord-strat,
                           AGR #agr,
                           CAT [ MC #mc,
                                 HEAD #head,
                                 VAL [ SPR #spr,
                                       SPEC #spec ] ],
                           CTXT #ctxt ],
                   NON-LOCAL #nonloc ] ],
    C-CONT.RELS <! !> ].


; --- 1.5.1. LR type for verbs 

; --- 1.5.1.1. Verbs taking verbal subjects
subj_vfin_vinf-lex-rule := vfin_vinf-lex-rule & 
  [ SYNSEM vinf-subj-synsem &
           [ LOCAL [ CAT.VAL [ SUBJ < [ LOCAL vp_inf_local &
                                              [ CAT.VAL [ SUBJ < [ NON-LOCAL [ SLASH 0-dlist,
                                                                               REL 0-dlist,
                                                                               QUE 0-dlist ] ] >,
                                                          CLTS < > ],
                                                CONT.HOOK.INDEX.SF prop ],
                                        NON-LOCAL #nloc ] >,
                               CLTS #clts ],
                     CONT [ HOOK [ LTOP #ltop,
                                   INDEX event & #index ],
                            RELS.LIST < #keyrel, ... > ] ],
             LKEYS.KEYREL #keyrel & [ LBL #ltop,
                                      ARG0 #index ] ], 
    DTR [ INFLECTED -,
          SYNSEM [ LOCAL.CAT.VAL [ SUBJ < [ NON-LOCAL #nloc ] >,
                                   CLTS #clts ],
                   LKEYS.KEYREL #keyrel ],
          ARG-ST #arg-st ],
    ARG-ST #arg-st ].

; a)- intransitive verbs taking finite/infinitival completive clause subjects and IO 
; - verbos de incumbencia: cuando está el IO este se interpreta como suj. del infinitivo, 
; cuando no está la construcción recibe una interpretación genérica.
; e.g. me conviene que vengas => (me) conviene ir
v_subj_prop_inf_or_fin_lex-rule := subj_vfin_vinf-lex-rule & 
  [ SYNSEM v_subj_cp_prop_inf_io_synsem &
           [ LOCAL.CAT.VAL.COMPS < unexpressed & 
                                   [ OPT +,
                                     CLTCZD -,
				     LOCAL #lcomp,
                                     NON-LOCAL #nlcomp ] > ],
    DTR.SYNSEM v_subj_cp_prop_inf_or_fin_io*_synsem &
               [ LOCAL.CAT [ VAL.COMPS < [ LOCAL #lcomp,
                                           NON-LOCAL #nlcomp ] > ] ] ].

v_subj_prop_inf_or_fin_io_lex-rule := subj_vfin_vinf-lex-rule & 
  [ SYNSEM v_subj_cp_prop_inf_io_synsem &
           [ LOCAL.CAT.VAL [ SUBJ < [ LOCAL.CONT.HOOK.XARG #ind ] >,
                             COMPS < [ OPT -,
                                       LOCAL #lcomp & [ CONT.HOOK.INDEX #ind ],
                                       NON-LOCAL #nlcomp ] > ] ],
    DTR.SYNSEM v_subj_cp_prop_inf_or_fin_io*_synsem &
               [ LOCAL.CAT.VAL.COMPS < [ LOCAL #lcomp,
                                         NON-LOCAL #nlcomp ] > ] ].

; - with "parecer" the IO is obligatory when it takes a VPinf subject
v_subj_prop_inf_or_fin_io-only_lex-rule := subj_vfin_vinf-lex-rule & 
  [ SYNSEM v_subj_cp_prop_inf_io_synsem &
           [ LOCAL.CAT.VAL [ SUBJ < [ LOCAL.CONT.HOOK.XARG #ind ] >,
                             COMPS < [ OPT -,
                                       LOCAL #lcomp & [ CONT.HOOK.INDEX #ind ],
                                       NON-LOCAL #nlcomp ] > ] ],
    DTR.SYNSEM v_subj_cp_prop_inf_or_fin_io_synsem &
               [ LOCAL.CAT.VAL.COMPS < [ LOCAL #lcomp,
                                         NON-LOCAL #nlcomp ] > ] ].

; - verbos af. psiquica: la cláusula alterna con VPinf sólo cuando el OI se interpreta como sujeto del inf
; e.g. me gustó que viniese => *(me) gusta llorar
v_subj_prop_fin_sub_io_lex-rule := subj_vfin_vinf-lex-rule & 
  [ SYNSEM v_subj_cp_prop_inf_io_synsem &
           [ LOCAL.CAT.VAL [ SUBJ < [ LOCAL.CONT.HOOK.XARG #ind ] >,
                             COMPS < [ OPT -,
                                       LOCAL #lcomp & [ CONT.HOOK.INDEX #ind ],
                                       NON-LOCAL #nlcomp ] > ] ],
    DTR.SYNSEM v_subj_cp_prop_fin_sub_io*_synsem &
               [ LOCAL.CAT.VAL.COMPS < [ LOCAL #lcomp,
                                         NON-LOCAL #nlcomp ] > ] ].


; b)- Intransitive verbs taking Vfin/VPinf subject and marked NP (no control)
; e.g. (el) que las clases sean malas repercute en los alumnos => llegar tarde a clase repercute en los alumnos
v_subj_cp_prop_inf_or_fin_sub_intr_mrkd_np_lex-rule := subj_vfin_vinf-lex-rule & 
  [ SYNSEM v_subj_cp_prop_inf_intr_mrkd_np_synsem &
           [ LOCAL.CAT.VAL.COMPS #comps ],
    DTR.SYNSEM v_subj_cp_prop_inf_or_fin_sub_intr_mrkd_np_synsem &
               [ LOCAL.CAT.VAL.COMPS #comps ] ].


; c)- Transitive verbs taking Vfin/VPinf subject and DO (no control)
; - e.g. que el poder político se descomponga no significa necesariamente una decadencia => perder no significa necesariamente una decadencia
v_subj_cp_prop_inf_or_fin_sub_trans_np_lex-rule := subj_vfin_vinf-lex-rule & 
  [ SYNSEM trans_vinf-subj-synsem & 
           [ LOCAL.CAT.VAL.COMPS #comps ],
    DTR.SYNSEM v_subj_cp_prop_inf_or_fin_sub_trans_np_synsem &
               [ LOCAL.CAT.VAL.COMPS #comps & < [ ] > ] ].

; d)- Transitive verbs taking Vfin subject, DO and marked NP (o_ctrl)
; e.g. trabajar la obliga a madrugar
v_subj_cp_prop_inf_or_fin_sub_trans_np_mrkd_np_lex-rule := subj_vfin_vinf-lex-rule & 
  [ SYNSEM trans_vinf-subj-synsem & 
           [ LOCAL.CAT.VAL [ SUBJ < [ LOCAL.CONT.HOOK.XARG #ind ] >,
                             COMPS #comps & < [ LOCAL.CONT.HOOK.INDEX #ind ],... > ] ],
    DTR.SYNSEM v_subj_cp_prop_inf_or_fin_sub_trans_np_mrkd_np_synsem &
               [ LOCAL.CAT.VAL.COMPS #comps ] ].

; e)- Transitive verbs taking Vfin/VPinf subject and completive clause (no control)
; e.g. que te haya aprobado no significa que no tengas que venir a clase => aprobar no significa que no tengas que venir a clase
v_subj_cp_prop_inf_or_fin_sub_trans_cp_prop_lex-rule := subj_vfin_vinf-lex-rule & 
  [ SYNSEM trans_vinf-subj-synsem & 
           [ LOCAL.CAT.VAL.COMPS #comps ],
    DTR.SYNSEM v_subj_cp_prop_fin_sub_trans_cp_prop_fin_synsem &
               [ LOCAL.CAT.VAL.COMPS #comps & < [ ] > ] ].

; f)- Ditransitive verbs taking Vfin subject (o_ctrl)
; e.g. tener que aguantar los embotellamientos te estropea el día
v_subj_cp_prop_inf_or_fin_sub_ditrans_lex-rule := subj_vfin_vinf-lex-rule & 
  [ SYNSEM v_subj_cp_prop_inf_ditrans_synsem &
           [ LOCAL.CAT.VAL [ SUBJ < [ LOCAL.CONT.HOOK.XARG #ind ] >,
                             COMPS #comps & < synsem, [ LOCAL.CONT.HOOK.INDEX #ind ] > ] ],
    DTR.SYNSEM v_subj_cp_prop_inf_or_fin_sub_ditrans_synsem &
               [ LOCAL.CAT.VAL.COMPS #comps ] ].

; g)- Ditransitive verbs taking Vfin subject, IO and finite completive clauses (o_ctrl)
; e.g. oír música no (te) impide trabajar
v_subj_cp_prop_inf_or_fin_sub_ditrans_cp_prop_lex-rule := subj_vfin_vinf-lex-rule & 
  [ SYNSEM v_subj_cp_prop_inf_ditrans_cp_prop_fin_synsem &
           [ LOCAL.CAT.VAL [ SUBJ < [ LOCAL.CONT.HOOK.XARG #ind ] >,
                             COMPS #comps & < [ LOCAL.CONT.HOOK.INDEX #ind ],... > ] ],
    DTR.SYNSEM v_subj_cp_prop_fin_sub_ditrans_cp_prop_fin_synsem &
               [ LOCAL.CAT.VAL.COMPS #comps ] ].


; --- 1.5.1.2. Verbs taking nominal subjects
vcomp_vfin_vinf-lex-rule := vfin_vinf-lex-rule & 
  [ SYNSEM [ LOCAL [ CAT.VAL.SUBJ #subj,
                     CONT [ HOOK [ LTOP #ltop,
                                   INDEX event & #index ],
                            RELS.LIST < #keyrel, ... > ] ],
             LKEYS.KEYREL #keyrel & [ LBL #ltop,
                                      ARG0 #index ] ], 
    DTR [ INFLECTED -,
          SYNSEM [ LOCAL.CAT.VAL.SUBJ #subj,
                   LKEYS.KEYREL #keyrel ] ] ].


; a)- intransitive verbs taking marked finite/infinitival completive clause (s_ctrl) or indirect questions
vintr_mrkd_cp_prop_lex-rule := vcomp_vfin_vinf-lex-rule & 
  [ SYNSEM v_intr_mrkd_cp_prop-or-ques_inf_synsem &
           [ LOCAL.CAT.VAL.COMPS < [ OPT -,
                                     LOCAL [ CAT.HEAD.KEYS #keys, 
                                             CONT.HOOK.INDEX.SF #sf ],
                                     NON-LOCAL #nloc ] > ],
    DTR.SYNSEM v_intr_mrkd_cp_prop-or-ques_fin_synsem &
               [ LOCAL.CAT.VAL.COMPS < [ LOCAL [ CAT.HEAD.KEYS #keys,
                                                 CONT.HOOK.INDEX.SF #sf ],
                                         NON-LOCAL #nloc ] > ] ].

; e.g. no renuncio a que vengas => no renunciaremos a trabajar 
v_intr_mrkd_cp_prop_lex-rule := vintr_mrkd_cp_prop_lex-rule &
  [ SYNSEM.LOCAL.CAT.VAL [ COMPS < [ LOCAL.CAT.VAL.CLTS #clts ] >,
                           CLTS #clts ], 
    DTR [ SYNSEM.LOCAL.CAT.VAL.CLTS < >,
          ARG-ST #arg-st ],
    ARG-ST < #arg-st . #clts > ].

; e.g. 
v_pron_intr_mrkd_cp_prop_lex-rule := vintr_mrkd_cp_prop_lex-rule &
  [ SYNSEM.LOCAL.CAT.VAL [ COMPS < [ LOCAL.CAT.VAL.CLTS #clts ] >,
                           CLTS < #clt . #clts > ],
    DTR [ SYNSEM.LOCAL.CAT.VAL.CLTS < #clt >,
          ARG-ST #arg-st ],
    ARG-ST < #arg-st . #clts > ].

; b)- transitive verbs taking finite/infinitival completive clause (clit. climbing) or indirect questions
; e.g. ¿has intentado que lo hagan? => ¿lo has intentado hacer tú?,
;      A y B acordaron no hablar => que no hablarían
v_trans_cp_prop_lex-rule := vcomp_vfin_vinf-lex-rule & 
  [ SYNSEM v_trans_cp_prop-or-ques_inf_synsem &
           [ LOCAL [ CAT.VAL [ COMPS < [ OPT -,
                                         LOCAL [ CAT [ HEAD.KEYS #keys, 
                                                       VAL.CLTS #clts ],
                                                 CONT.HOOK.INDEX.SF #sf ],
                                         NON-LOCAL #nloc ] >,
                               CLTS #clts ] ]  ],
    DTR [ SYNSEM v_trans_cp_prop-or-ques_fin_synsem &
                 [ LOCAL.CAT.VAL [ COMPS < [ LOCAL [ CAT.HEAD.KEYS #keys,
                                                 CONT.HOOK.INDEX.SF #sf ],
                                             NON-LOCAL #nloc ] >,
                                   CLTS < > ] ],
          ARG-ST #arg-st ],
    ARG-ST < #arg-st . #clts >  ].

; c)- ditransitive verbs taking finite/infinitival completive clause or indirect questions
; - si el verbo principal lleva un clítico: si el acusativo incrustado es personal, este no puede 
; elevarse (*me la permitieron educar), si se trata de no animados, puede elevarse 
; (me lo permitieron corregir)
v_ditrans_cp_prop_lex-rule := vcomp_vfin_vinf-lex-rule & 
  [ SYNSEM v_ditrans_cp_prop-or-ques_inf_synsem &
           [ LOCAL.CAT.VAL [ COMPS < [ LOCAL #local,
                                       NON-LOCAL #nloc1 ],
                                     [ OPT -,
                                       LOCAL [ CAT [ HEAD.KEYS #keys, 
                                                     VAL.CLTS #clts ],
                                               CONT.HOOK.INDEX.SF #sf ],
                                       NON-LOCAL #nloc ] >,
                             CLTS #clts ] ],
    DTR [ SYNSEM v_ditrans_cp_prop-or-ques_fin_synsem &
                 [ LOCAL.CAT.VAL [ COMPS < [ LOCAL #local,
                                             NON-LOCAL #nloc1 ],
                                           [ LOCAL [ CAT.HEAD.KEYS #keys,
                                                 CONT.HOOK.INDEX.SF #sf ],
                                             NON-LOCAL #nloc ] >,
                                   CLTS < > ] ],
          ARG-ST #arg-st ],
    ARG-ST < #arg-st . #clts > ].

; e.g. prometí a María que volverían temprano => prometí a María volver temprano
v_ditrans_cp_prop_sc_lex-rule := v_ditrans_cp_prop_lex-rule &
  [ SYNSEM.LOCAL.CAT.VAL [ SUBJ  < [ LOCAL.CONT.HOOK.INDEX ref-ind & #ind1 ] >,
                           COMPS < [ OPT #opt ],
                                   [ LOCAL.CONT.HOOK.XARG #ind1 ] > ],
    DTR.SYNSEM.LOCAL.CAT.VAL.COMPS < [ OPT #opt ],
                                     [ LOCAL.CAT.HEAD.TAM.MOOD ind ] > ].

; e.g. ordené a María que volviesen temprano => ordené a María volver temprano
v_ditrans_cp_prop_oc_lex-rule := v_ditrans_cp_prop_lex-rule &
  [ SYNSEM.LOCAL.CAT.VAL.COMPS < [ OPT -, LOCAL.CONT.HOOK.INDEX ref-ind & #ind2 ],
                                 [ LOCAL.CONT.HOOK.XARG #ind2 ] >,
    DTR.SYNSEM.LOCAL.CAT.VAL.COMPS < synsem,
                                     [ LOCAL.CAT.HEAD.TAM.MOOD sub ] > ].


; d)- transitive verbs taking DO and marked finite/infinitival completive clause (only verbs of movement)
v_trans_np_mrkd_cp_prop_lex-rule := vcomp_vfin_vinf-lex-rule & 
  [ SYNSEM v_trans_np_mrkd_cp_prop_inf_synsem &
           [ LOCAL.CAT.VAL.COMPS < [ OPT #opt,
                                     NON-LOCAL #nloc1 ],
                                   [ OPT -,
                                     NON-LOCAL #nloc ] > ],
    DTR.SYNSEM v_trans_np_mrkd_cp_prop_fin_sub_mov_synsem &
               [ LOCAL.CAT.VAL.COMPS < [ OPT #opt,
                                         NON-LOCAL #nloc1 ],
                                       [ NON-LOCAL #nloc ] > ] ].

; -- subject control (no clitic climbing)
; e.g. la amenazó con ir a la policía
v_trans_np_mrkd_cp_prop_sc_lex-rule := v_trans_np_mrkd_cp_prop_lex-rule &
  [ SYNSEM.LOCAL.CAT.VAL [ SUBJ  < [ LOCAL.CONT.HOOK.INDEX ref-ind & #ind1 ] >,
                           COMPS < synsem,
                                   [ LOCAL [ CAT.VAL.CLTS < >,
                                             CONT.HOOK.XARG #ind1 ] ] >,
                           CLTS #clts ],
    DTR [ SYNSEM.LOCAL.CAT.VAL.CLTS #clts & < >,
          ARG-ST #arg-st ],
    ARG-ST #arg-st ].

;; --- two-object control (with VPtrans sharing the same DO with the main clause) (ONLY IN LRs)
; e.g. envía las camisas a planchar a madrid, llévala a arreglar.
v_trans_np_mrkd_cp_prop_2oc_lex-rule := v_trans_np_mrkd_cp_prop_lex-rule &
  [ SYNSEM.LOCAL.CAT.VAL [ COMPS < [ LOCAL.CONT.HOOK.INDEX #ctrl ],
                                   [ LOCAL [ CAT.VAL.CLTS #clt,
                                             CONT.RELS.LIST < arg12-ev-relation & [ ARG2 #ctrl ],... > ] ] >,
                           CLTS #clt ],
    DTR [ SYNSEM.LOCAL.CAT.VAL.CLTS < >,
          ARG-ST #arg-st ],
    ARG-ST < #arg-st . #clt > ].

; f)- transitive symmetric verbs taking marked NP and completive clause (inf/fin) (s_ctrl) / 
;     pl. subject and completive clause 
; e.g. A acordó con B no hablar/que no hablarían
v_sym_trans_cp_prop_mrkd_np_lex-rule := vcomp_vfin_vinf-lex-rule & 
  [ SYNSEM v_sym_trans_cp_prop_inf_mrkd_np_synsem &
           [ LOCAL [ CAT.VAL [ COMPS < #synsem, 
                                       [ OPT -,
                                         LOCAL.CAT.VAL.CLTS #clts,
                                         NON-LOCAL #nloc ] >,
                               CLTS #clts ] ] ],
    DTR [ SYNSEM v_sym_trans_cp_prop_fin_mrkd_np_synsem &
                 [ LOCAL.CAT.VAL [ COMPS < #synsem, [ NON-LOCAL #nloc ] >,
                                   CLTS < > ] ],
          ARG-ST #arg-st ],
    ARG-ST < #arg-st . #clts > ].


; e)- intransitive symmetric verbs taking marked NP and marked completive clause (inf/fin) (s_ctrl) /
; pl. subject and marked completive clause 
; e.g. quedé con ella en ir al cine / quedamos en ir al cine
; !!! not used so far
; v_sym_intr_mrkd_np_mrkd_cp_prop_lex-rule := vcomp_vfin_vinf-lex-rule & 
;   [ SYNSEM v_intr_mrkd_np_mrkd_cp_prop_inf_sym_synsem &
;            [ LOCAL [ CAT.VAL [ COMPS < #synsem, 
;                                        [ OPT -,
;                                          LOCAL.CAT.VAL.CLTS #clts,
;                                          NON-LOCAL #nloc ] >,
;                                CLTS #clts ] ] ],
;     DTR [ SYNSEM v_intr_mrkd_np_mrkd_cp_prop_fin_sym_synsem &
;                  [ LOCAL.CAT.VAL [ COMPS < #synsem, [ NON-LOCAL #nloc ] >,
;                                    CLTS < > ] ],
;           ARG-ST < #arg-st > ],
;     ARG-ST < #arg-st . #clts > ].


; --- 1.5.2. LR type for nouns 

; a)- taking finite/infinitival completive clause & interrogative clauses (i.e. n_cp_prop_count_le / n_cp_ques_count_le)
; e.g. una ventaja (de) que no llueva es que no hay ocasión de perder el paraguas => otra ventaja de viajar en tren es que se pueden cargar más bultos   
n_mrkd_prop-or-ques_lex-rule := vfin_vinf-lex-rule & 
  [ SYNSEM n_mrkd_cp_prop-or-ques_inf_synsem &
           [ LOCAL.CAT.VAL.COMPS < [ OPT -,
                                     LOCAL mrkd_or_unmrkd_cp_prop_or_ques_local &
                                           [ CAT.HEAD.KEYS #keys, 
                                             CONT.HOOK.INDEX.E [ TENSE nontense,
                                                                 ASPECT no-aspect ] ],
                                      NON-LOCAL #nlocal ] >,
             LKEYS.KEYREL #keyrel ],
    DTR [ INFLECTED +,
          SYNSEM [ LOCAL.CAT [ HEAD noun,
                               VAL.COMPS < [ LOCAL mrkd_or_unmrkd_cp_prop_or_ques_local &
                                                   [ CAT.HEAD.KEYS #keys,
                                                     CONT.HOOK.INDEX.E [ TENSE tense,
                                                                         MOOD ind_or_sub_mood ] ],
                                             NON-LOCAL #nlocal ] > ],
                   LKEYS.KEYREL #keyrel ] ] ].

; b)- taking PPde + finite completive clause/VPinf_ctrl (i.e. n_ppde_cp_prop_fin_mass_le/n_ppde_cp_prop_fin_count_le)
; e.g. la necesidad (de la empresa) (de) que lleguen a un acuerdo/de llegar a un acuerdo 
n_ppde_prop-or-ques_lex-rule := vfin_vinf-lex-rule & 
  [ SYNSEM n_ppde_cp_prop_inf_synsem &
           [ LOCAL.CAT.VAL.COMPS < #synsem & [ LOCAL.CONT.HOOK.INDEX #ctrl ],
                                   [ OPT -,
                                     LOCAL [ CAT.HEAD.KEYS #keys,
                                             CONT.HOOK [ XARG #ctrl,
                                                         INDEX [ SF #sf,
                                                                 E [ TENSE nontense,
                                                                     ASPECT no-aspect ] ] ] ],
                                      NON-LOCAL #nlocal ] >,
             LKEYS.KEYREL #keyrel ],
    DTR [ INFLECTED +,
          SYNSEM n_ppde_cp_prop_fin_synsem & 
                 [ LOCAL.CAT [ HEAD noun,
                               VAL.COMPS < #synsem,
                                           [ LOCAL [ CAT.HEAD.KEYS #keys,
                                                     CONT.HOOK.INDEX [ SF #sf,
                                                                       E [ TENSE tense,
                                                                           MOOD ind_or_sub_mood ] ] ],
                                             NON-LOCAL #nlocal ] > ],
                   LKEYS.KEYREL #keyrel ] ] ].


; --- 1.5.3. LR type for adjectives taking finite/infinitival completive clause or questions
; e.g. es bastante partidario (de) que cambien al entrenador/de cambiar al entrenador
a_mrkd_prop-or-ques_lex-rule := vfin_vinf-lex-rule & 
  [ SYNSEM a_mrkd_cp_prop-or-ques_inf_synsem &
           [ LOCAL [ CAT [ HEAD.MOD < [ LOCAL.CONT.HOOK.INDEX #ind ] >,
                           VAL [ CLTS < >,
                                 SUBJ #subj,
                                 COMPS < [ OPT -,
                                           LOCAL mrkd_or_unmrkd_cp_prop_or_ques_local &
                                                 [ CAT.HEAD.KEYS #keys, 
                                                   CONT.HOOK [ LTOP #larg,
                                                               INDEX.E [ TENSE nontense,
                                                                         ASPECT no-aspect ] ] ],
                                           NON-LOCAL #nlocal ] > ] ],
                     CONT [ HOOK.XARG #ind,
                            RELS <! adj-arg12-relation !>,
                            HCONS <! qeq & [ HARG #harg,
                                             LARG #larg ] !> ] ],
             LKEYS.KEYREL #keyrel & [ ARG2 #harg ] ],
    DTR [ INFLECTED -,
          SYNSEM [ LOCAL.CAT [ HEAD adj,
                               VAL [ SUBJ #subj,
                                     COMPS < [ LOCAL mrkd_or_unmrkd_cp_prop_or_ques_local &
                                                     [ CAT.HEAD.KEYS #keys,
                                                       CONT.HOOK.INDEX.E [ TENSE tense,
                                                                           MOOD ind_or_sub_mood ] ],
                                               NON-LOCAL #nlocal ] > ] ],
                   LKEYS.KEYREL #keyrel ] ] ].


; --- 2. LR types for participles

; --- 2.1. LR type building pastparts for passive constructions
ppart-lex-rule := const-ltol-rule & 
  [ ALTS [ PASS -,
           PERM #perm ],
    SYNSEM [ PUNCT #punct,
             LOCAL [ AGR #agr,
                     CAT [ MC #mc,
                           HEAD verb & [ INV -,
                                         AUX -,
                                         PRD predicative & 
                                             [ COPULA ser ],
                                         VFORM part,
                                         VOICE passive,
                                         TAM #tam & [ MOOD #mood ],
                                         KEYS.KEY #key,
                                         MOD < > ], 
                           VAL [ SPR #spr,
                                 SUBJ < unexpressed & 
                                        [ OPT -, 
                                          LOCAL np_nom_local & 
                                                [ AGR #agr,
                                                  CONT #objcont & [ HOOK.INDEX #agr ] ], 
                                          NON-LOCAL #ononloc & [ SLASH 0-dlist ] ] >,
                                 COMPS < [ OPT +,
                                           LOCAL mrkd_np_local & 
                                                 [ CAT.HEAD.KEYS.KEY _por_p_sel_rel,
                                                   CONT.HOOK [ INDEX #subjind ] ],
                                           NON-LOCAL #snonloc ]. #comps >,
                                 CLTS #clts] ],
                     CONT [ HOOK [ INDEX #index,
                                   LTOP #hand,
                                   XARG #agr ],
                            RELS #rels & [ LIST < [ ARG0 #index & [ E.MOOD #mood ],
                                                    ARG2 #agr ], ... > ],
                            HCONS #hcons ],
                     CTXT #ctxt ],
            LKEYS #lkeys,
            NON-LOCAL #nonloc ],
    DTR [ INFLECTED +,
          ALTS [ PASS +,
                 PERM #perm ],
          SYNSEM [ PUNCT #punct & [ RPUNCT no_punct ],
                   LOCAL [ CAT [ MC #mc,
                                 HEAD verb &
                                      [ PRD non-predicative,
                                        VFORM part,
                                        VOICE active,
                                        TAM #tam,
                                        KEYS.KEY #key ],
                                 VAL [ SPR #spr,
                                       SUBJ < [ LOCAL np_nom_local & 
                                                      [ CONT.HOOK.INDEX #subjind ],
                                                NON-LOCAL #snonloc ] >,
                                       COMPS [ FIRST [ LOCAL [ CONT #objcont ],
                                                       NON-LOCAL #ononloc ], 
                                               REST #comps ],
                                       CLTS #clts ] ],
                           CONT [ HOOK [ LTOP #hand ],
                                  HCONS #hcons,
                                  RELS #rels ],
                           CTXT #ctxt ],
                   LKEYS #lkeys,
                   NON-LOCAL #nonloc ] ] ].

; --- 2.2. LR type building pastpart in predicative position co-occuring with "estar"
; e.g. la sopa está comida (*por los chicos)
attr-part-lex-rule := const-ltol-rule  &
  [ SYNSEM [ PUNCT #punct,
             LOCAL [ AGR #ind,
                     CAT [ MC #mc,
                           HEAD verb &
                               [ AUX -,
                                 VFORM part,
                                 VOICE active,
                                 PRD predicative & 
                                     [ COPULA estar ],
                                 CLIT #case,
                                 KEYS.KEY #key,
                                 MOD < synsem &
                                       [ LOCAL intersective-mod &
                                               [ AGR #ind,
                                                 CAT [ HEAD noun,
                                                       VAL.SPR < synsem > ], 
                                                 CONT.HOOK.INDEX #ind ] ] > ],
                          VAL [ SUBJ < unexpressed & 
                                       [ OPT -, 
                                         LOCAL #subj & [ CONT.HOOK.INDEX #ind ] ] >,
                                SPR #spr,
                                COMPS #comps,
                                CLTS #clts,
                                SPEC < > ],
                          MC na ],
                    CONT [ HOOK [ LTOP #ltop,
                                  INDEX #event,
                                  XARG #ind ],
                           RELS #rels,
                           HCONS #hcons ],
                    CTXT #ctxt ],
	    NON-LOCAL #non-local ],
    DTR [ INFLECTED +,
          SYNSEM [ PUNCT #punct & [ RPUNCT no_punct ],
                   LOCAL [ AGR #ind,
                           CAT [ MC #mc,
                                 HEAD verb &
                                      [ AUX -,
                                        VFORM part,
                                        VOICE passive,
                                        PRD predicative, 
                                        KEYS.KEY #key,
                                        CLIT #case,
                                        MOD < > ],
				 VAL [ SUBJ < [ LOCAL #subj ] >,
                                       COMPS < [ LOCAL mrkd_np_local &
                                                       [ CAT.HEAD.KEYS.KEY _por_p_sel_rel ] ]. #comps >,
                                       CLTS #clts & < >,
                                       SPR #spr ] ],
                           CONT [ HOOK [ LTOP #ltop,
                                         INDEX #event ],
                                  RELS #rels & <! relation !>,
                                  HCONS #hcons ],
                           CTXT #ctxt ],
                   NON-LOCAL #non-local ] ],
    C-CONT.RELS <! !> ].

; --- 2.3. LR for pastparts modifying nouns
adj_part-lex-rule := const-ltol-rule  &
  [ SYNSEM [ PUNCT #punct,
             LOCAL [ AGR #ind,
                     CAT [ MC #mc,
                           POSTHEAD +,
                           HEAD adj &
                               [ PRD non-predicative,
                                 MOD < synsem &
                                       [ LOCAL intersective-mod &
                                               [ AGR #ind,
                                                 CAT [ HEAD noun,
                                                             VAL [ SPR < [ LOCAL.CAT.HEAD.KEYS.KEY quant_or_deg_rel]>,
                                                             SUBJ < >,
                                                             SPEC < > ] ], 
                                                 CONT.HOOK.INDEX #ind ] ] >,
                                 KEYS.KEY adj_rel ],
                          VAL [ SUBJ < >,
                                SPR < [ OPT +,
                                        LOCAL [ CAT [ HEAD.KEYS.KEY degree_rel,
                                                      VAL.COMPS < >,
                                                      MC na ],
                                                CONT.HOOK [ LTOP #ltop,
                                                            XARG #event ] ],
                                        NON-LOCAL [ SLASH 0-dlist,
                                                    QUE 0-dlist ] ] >,
                                COMPS #comps,
                                CLTS #clts,
                                SPEC < > ],
                          MC na ],
                    CONT.HOOK [ LTOP #ltop,
                                INDEX #event,
                                XARG #ind ],
                    CTXT #ctxt ],
	    NON-LOCAL #non-local & [ QUE 0-dlist ] ],
    DTR [ INFLECTED +,
          SYNSEM [ PUNCT #punct & [ RPUNCT no_punct ],
                   LOCAL [ AGR #ind,
                           CAT [ MC #mc,
                                 HEAD verb &
                                      [ AUX -,
                                        VFORM part,
                                        VOICE passive,
                                        PRD predicative, 
                                        MOD < > ],
				 VAL [ SUBJ < [ LOCAL.CONT.HOOK.INDEX #ind ] >,
                                       COMPS #comps & 
                                             < [ LOCAL mrkd_np_local &
                                                       [ CAT.HEAD.KEYS.KEY _por_p_sel_rel ] ],... >,
                                       CLTS #clts & < > ] ],
                           CONT.HOOK.INDEX #event,
                           CTXT #ctxt ],
                   NON-LOCAL #non-local ] ],
    C-CONT [ HOOK [ INDEX #event,
                    XARG #ind ],
             RELS <!  !>,
             HCONS <! !> ] ].


; --- 3. LR types building indef. adjectives
; for "evaluativos" quantifiers (otro, mucho/poco, bastante,...). These may co-occur in 
; predicative constructions (e.g. sus problemas eran demasiados) or as pre-nominal adjectives 
; (e.g. sus demasiados problemas).
indef-adj-lex-rule := basic-lex-rule & phrase-or-lexrule & 
  [ STEM #stem,
    INFLECTED #infl,
    SYNSEM [ PUNCT #punct,
             LOCAL [ AGR #agr,
                     CAT [ POSTHEAD -,
                           MC na,
                           HEAD adj &
                                [ KEYS.KEY #pred,
                                  TAM #tam,
                                  MOD < [ LOCAL intersective-mod & 
                                           [ CAT [ HEAD noun & [ KEYS.KEY non_elliptical_n_rel ],
                                                   VAL [ SPR < expressed-synsem & 
                                                               [LOCAL.CAT.HEAD.KEYS.KEY quant_or_deg_rel]>,
                                                         SUBJ < >,
                                                         SPEC < > ] ],
                                             CONT.HOOK.INDEX #agr ] ] > ],
                           VAL [ SPR < >,
                                 SUBJ < >,
                                 COMPS < >,
                                 CLTS < > ] ],
                     CONT [ HOOK [ LTOP #ltop,
                                   INDEX #arg0,
                                   XARG #agr ],
                            RELS <! #key & adj-arg1-relation & 
                                    [ ARG0.E #tam ] !> ] ],
            LKEYS.KEYREL #key & [ PRED #pred,
                                  LBL #ltop,
                                  ARG0 #arg0,
                                  ARG1 #agr ],
            NON-LOCAL #nonloc ],
    DTR [ STEM #stem,
          INFLECTED #infl,
          SYNSEM [ PUNCT #punct & [ RPUNCT no_punct ],
                   LOCAL [ AGR #agr,
                           CAT.HEAD det,
                           CONT.RELS <! relation, relation !> ],
                   LKEYS.ALTKEYREL.PRED card_or_undef_q_rel & #pred,
                   NON-LOCAL #nonloc & non-local-none ] ],
    C-CONT.RELS <! !> ].


; otro
otro_indef_adj-lex-rule := indef-adj-lex-rule &
  [ SYNSEM.LOCAL.CAT.HEAD.MOD < [ LOCAL.CAT.VAL.SPR < [ LOCAL.CAT.HEAD.KEYS.KEY pre_otro_q_rel ] > ] >,
    DTR.SYNSEM.LKEYS.ALTKEYREL.PRED otro_q_rel ].

; mucho/poco 
mucho_or_poco_indef_adj-lex-rule := indef-adj-lex-rule &
  [ SYNSEM.LOCAL.CAT.HEAD.MOD < [LOCAL.CAT.VAL.SPR < [LOCAL.CAT.HEAD.KEYS.KEY pre_much_or_poc_q_rel] >] >,
    DTR.SYNSEM.LKEYS.ALTKEYREL.PRED mucho_or_poco_q_rel ].

; varios, bastante, demasiado, numeroso, determinado, distinto, diverso, escaso, cierto, raro
undef_q_indef_adj-lex-rule := indef-adj-lex-rule &
  [ SYNSEM.LOCAL.CAT.HEAD.MOD < [ LOCAL.CAT.VAL.SPR < [ LOCAL.CAT.HEAD.KEYS.KEY def_q_rel ] > ] >,
    DTR.SYNSEM.LKEYS.ALTKEYREL.PRED undef_q_rel ].

; cardinals
card_q_indef_adj-lex-rule := indef-adj-lex-rule &
  [ SYNSEM.LOCAL.CAT.HEAD.MOD < [ LOCAL.CAT.VAL.SPR < [ LOCAL.CAT.HEAD.KEYS.KEY pre_card_q_rel ] > ] >,
    DTR [ INFLECTED -,
          SYNSEM.LKEYS.ALTKEYREL.PRED card_q_rel ] ].


; --- 4. LR types for determiners/quantifiers following the noun
postn-det-lex-rule := basic-lex-rule & phrase-or-lexrule & 
  [ STEM #stem,
    INFLECTED #infl,
    ALTS #alts,
    SYNSEM [ MODIFIED #modified,
             PUNCT #punct,
             LOCAL [ COORD #coord,
                     COORD-REL #coord-rel,
                     COORD-STRAT #coord-strat,
                     CAT [ POSTHEAD +,
                           MC na,
                           VAL [ SPR < >,
                                 SUBJ < >,
                                 COMPS < >,
                                 CLTS < > ] ] ],
            NON-LOCAL #nonloc ],
    DTR [ STEM #stem,
          INFLECTED #infl & +,
          ALTS #alts,
          SYNSEM [ MODIFIED #modified,
                   PUNCT #punct & [ RPUNCT no_punct ],
                   LOCAL [ COORD #coord,
                           COORD-REL #coord-rel,
                           COORD-STRAT #coord-strat,
                           CAT.HEAD det ],
                   NON-LOCAL #nonloc & non-local-none ] ],
    C-CONT.RELS <! !> ].

postn-adj-det-lex-rule := postn-det-lex-rule &
  [ SYNSEM [ LOCAL [ AGR #agr,
                     CAT [ MC na,
                           HEAD adj &
                              [ TAM #tam,
                                KEYS.KEY #pred,
                                MOD < [ LOCAL intersective-mod & 
                                              [ CAT [ HEAD noun,
                                                      VAL [ SUBJ < >,
                                                            SPEC < > ] ],
                                                CONT.HOOK.INDEX #agr ] ] > ] ],
                     CONT [ HOOK [ INDEX #arg0,
                                   LTOP #ltop,
                                   XARG #agr ],
                            RELS <! #key & adj-arg1-relation & 
                                    [ ARG0.E #tam ] !> ] ],
            LKEYS.KEYREL #key & [ PRED #pred,
                                  ARG0 #arg0,
                                  LBL #ltop,
                                  ARG1 #agr ] ],
    DTR.SYNSEM.LOCAL.AGR #agr ].

; - demonstratives: when they follow the noun, they are modifiers and they require 
; the definite article (e.g. la canción esa me gustó)
postn-dem-lex-rule := postn-adj-det-lex-rule &
  [ SYNSEM [ LOCAL.CAT.HEAD.MOD < [ LOCAL.CAT [ HEAD.KEYS.ALTKEY _el_q_rel,
                                                VAL.SPR < [ LOCAL.CAT.HEAD.KEYS.KEY quant_rel ] > ] ] >,
             LKEYS.KEYREL.PRED dem_adj_rel ],
    DTR.SYNSEM [ LOCAL.CAT.POSTHEAD -,
                 LKEYS.KEYREL.PRED dem_q_rel ] ].

; - alguno/ninguno always follow the noun (e.g. no tengo miedo alguno) and 
; alguna/os/as, ninguna may precede and follow the noun
postn-quant-lex-rule := postn-det-lex-rule &
  [ SYNSEM [ LOCAL [ AGR #agr,
                     CAT.HEAD #head,
                     CONT #cont ],
             LKEYS #lkey ],
    DTR.SYNSEM [ LOCAL [ AGR #agr,
                         CAT [ POSTHEAD -,
                               HEAD #head ],
                         CONT #cont ],
                 LKEYS #lkey ] ].


postn-alg-lex-rule := postn-quant-lex-rule &
  [ DTR.SYNSEM.LKEYS.KEYREL.PRED _alguno_q_rel ].

postn-ning-lex-rule := postn-quant-lex-rule &
  [ DTR.SYNSEM.LKEYS.KEYREL.PRED _ninguno_q_rel ].


; --- 4. LR types for deverbal nouns

nom-val-alt-lr := basic-lex-rule & phrase-or-lexrule & 
  [ INFLECTED #infl,
    STEM #stem,
    SYNSEM [ MODIFIED #modified,
             PUNCT #punct,
             LOCAL [ AGR #agr,
                     CAT [ MC #mc,
                           HEAD #head, 
                           VAL [ SPEC #spec,
                                 SUBJ #subj,
                                 CLTS #clts ] ],
                     CONT [ HOOK [ LTOP #ltop,
                                   INDEX #agr,
                                   XARG #xarg ], 
                            RELS [ LIST [ FIRST #keyrel &
                                                [ LBL #lbl,
                                                  WLINK #wlink,
                                                  PRED #pred,
                                                  ARG0 #agr ],
                                          REST #rest ],
                                   LAST #last ],
                            HCONS #hcons ],
                     CTXT #ctxt ],
            NON-LOCAL #nonloc,
            LKEYS [ KEYREL #keyrel, 
                    --COMPKEY #ckey ] ],
    DTR [ INFLECTED #infl& -,
          STEM #stem,
          SYNSEM [ MODIFIED #modified & notmod,
                   PUNCT #punct & [ RPUNCT no_punct ],
                   LOCAL [ CAT [ MC #mc,
                                 HEAD #head & noun,
                                 VAL [ SPEC #spec,
                                       SUBJ #subj,
                                       CLTS #clts ] ],
                           CONT [ HOOK [ LTOP #ltop,
                                         XARG #xarg ],
                                  RELS [ LIST [ FIRST [ LBL #lbl,
                                                        WLINK #wlink,
                                                        PRED #pred ],
                                                REST #rest ],
                                         LAST #last ],
                                  HCONS #hcons ],
                           CTXT #ctxt ],
                   NON-LOCAL #nonloc,
                   LKEYS.--COMPKEY #ckey ] ],
    C-CONT.RELS <! !> ].

; --- 4.1. rule producing nouns denoting results (heads of active NPs) from (ambiguous) unaccusative
; nouns denoting events/processes & results
; e.g. la crecida [del río] (event/process & result) => la crecida ([del río/fluvial]) (result)
;      la llegada [del niño] ([al cole]) (event/process & result) => la llegada al cole (result)
ambiguous-nom-act-lex-rule := nom-val-alt-lr &
  [ ALTS [ PERM -,
           PASS - ],
    SYNSEM result-noun-synsem & 
           [ LOCAL [ CAT.VAL [ SPR < [ LOCAL.CONT.RELS <! relation !> ] >,
                               COMPS < unexpressed & 
                                       [ OPT +,
                                         LOCAL #local-comp,
                                         NON-LOCAL #nlocal-comp ]. #comps > ],
                     CONT.RELS <! noun-arg2-relation & 
                                  [ ARG2 #arg2 ] !> ] ],
    DTR [ ALTS.PASS -,
          SYNSEM event-or-process_and_result-noun-synsem & 
                 [ LOCAL [ CAT.VAL.COMPS < [ OPT -,
                                             LOCAL #local-comp,
                                             NON-LOCAL #nlocal-comp ]. #comps >,
                           CONT.RELS <! noun-arg2-relation & 
                                        [ ARG2 #arg2 ] !> ] ] ] ].

; --- 4.2. rule producing nouns denoting events/processes (heads of passive NPs) from transitive 
; nouns denoting results (heads of active NPs)
; e.g. el descubrimiento ([de un científico francés]) ([del virus]) (result) 
;      el descubrimiento [del virus] [por un científico francés] => event/process
;      el descubrimiento [del virus] => ambiguous: event/process & result

nom-pass-lex-rule := nom-val-alt-lr & 
  [ ALTS [ PERM -,
           PASS + ],
    SYNSEM event-or-process-noun-synsem & 
           [ LOCAL [ CAT.VAL [ SPR #spr,
                               COMPS < [ OPT -,
                                         LOCAL #local-comp2, 
                                         NON-LOCAL #nlocal-comp2 ],  
                                       [ OPT +,
                                         LOCAL mrkd_np_local & 
                                               [ CAT [ HEAD.KEYS.KEY _por_p_sel_rel,
                                                       VAL #val-comp1 ],
                                                 CONT #cont-comp1 ], 
                                         NON-LOCAL #nlocal-comp1 ] > ],
                     CONT.RELS <! noun-arg12-relation & 
                                  [ ARG1 #arg1,
                                    ARG2 #arg2 ] !> ] ],
    DTR [ ALTS.PASS +,
          SYNSEM result-noun-synsem & 
                 [ LOCAL [ CAT.VAL [ SPR #spr,
                                     COMPS < [ OPT +,
                                               LOCAL mrkd_np_local & 
                                                     [ CAT [ HEAD.KEYS.KEY _de_p_sel_rel,
                                                             VAL #val-comp1 ],
                                                       CONT #cont-comp1 ], 
                                               NON-LOCAL #nlocal-comp1 ],
                                             [ OPT +,
                                               LOCAL #local-comp2 & 
                                                     [ CAT.HEAD.KEYS.KEY _de_p_sel_rel ], 
                                               NON-LOCAL #nlocal-comp2 ] > ],
                           CONT.RELS <! noun-arg12-relation & 
                                        [ ARG1 #arg1,
                                          ARG2 #arg2 ] !> ] ] ] ].


; --- 4.3. rules producing nouns denoting results (heads of active NPs) from transitive n., ditransitive n.
; and transive nouns with locational complements denoting events-processes (heads of passive NPs)
; e.g. la construcción [de la casa] ([por los albañiles]) (event/process) 
;      => la construcción (result)
; e.g. el envío [del paquete] [a sus destinatarios] [por el remitente] (event/process) 
;      => el envío (result)
; e.g. la colocación *([de los cuadros]) ([en las paredes]) ([por los habitantes de la casa])
;      => la colocación (result)
;bivalent-nom-act-lex-rule := nom-val-alt-lr &
;  [ ALTS.PASS -,
;    SYNSEM result-noun-synsem & 
;                 [ LOCAL [ CAT.VAL [ SPR #spr,
;                                     COMPS < unexpressed & 
;                                             [ OPT +,
;                                               LOCAL #local-comp,
;                                               NON-LOCAL #nlocal-comp ],
;                                             unexpressed & #comp2 > ],
;                           CONT.RELS <! noun-arg12-relation & 
;                                        [ ARG1 #arg1,
;                                          ARG2 #arg2 ] !> ] ],
;    DTR [ ALTS.PASS -,
;          SYNSEM event-or-process-noun-synsem & 
;                 [ LOCAL [ CAT.VAL [ SPR #spr,
;                                     COMPS < [ OPT -,
;                                               LOCAL #local-comp,
;                                               NON-LOCAL #nlocal-comp ], #comp2 > ],
;                           CONT.RELS <! noun-arg12-relation & 
;                                        [ ARG1 #arg1,
;                                          ARG2 #arg2 ] !> ] ] ] ].
;
;trivalent-nom-act-lex-rule := nom-val-alt-lr &
;  [ ALTS.PASS -,
;    SYNSEM result-noun-synsem & 
;                 [ LOCAL [ CAT.VAL [ SPR #spr,
;                                     COMPS < [ OPT +,
;                                               LOCAL #local-comp,
;                                               NON-LOCAL #nlocal-comp ],
;                                             [ OPT +,
;                                               LOCAL #local-comp2,
;                                               NON-LOCAL #nlocal-comp2 ],
;                                             unexpressed & #comp3 > ],
;                           CONT.RELS <! noun-arg123-relation & 
;                                        [ ARG1 #arg1,
;                                          ARG2 #arg2,
;                                          ARG3 #arg3 ] !> ] ],
;    DTR [ ALTS.PASS -,
;          SYNSEM event-or-process-noun-synsem & 
;                 [ LOCAL [ CAT.VAL [ SPR #spr,
;                                     COMPS < [ OPT -,
;                                               LOCAL #local-comp,
;                                               NON-LOCAL #nlocal-comp ],
;                                             [ OPT -,
;                                               LOCAL #local-comp2,
;                                               NON-LOCAL #nlocal-comp2 ],
;                                             #comp3 > ],
;                           CONT.RELS <! noun-arg123-relation & 
;                                        [ ARG1 #arg1,
;                                          ARG2 #arg2,
;                                          ARG3 #arg3 ] !> ] ] ] ].


; --- 5. LR types for partitive pronouns/quantifying nouns

partitive-lex-rule := basic-lex-rule & phrase-or-lexrule & 
  [ STEM #stem,
    INFLECTED #infl,
    ALTS #alts,
    SYNSEM [ MODIFIED #modified & notmod,
             PUNCT #punct,
             LOCAL [ CAT [ MC na,
                           VAL [ SPEC #spec,
                                 SUBJ #subj,
                                 CLTS #clts,
                                 COMPS < > ] ],
                     CONT.HCONS #hcons, 
                     CTXT #ctxt ] ],
    DTR [ STEM #stem,
          INFLECTED #infl & -,
          ALTS #alts,
          SYNSEM [ MODIFIED #modified,
                   PUNCT #punct & [ RPUNCT no_punct ],
                   LOCAL [ CAT [ VAL [ SPEC #spec,
                                       SUBJ #subj,
                                       CLTS #clts ] ], 
                           CONT.HCONS #hcons, 
                           CTXT #ctxt ] ] ] ].

group_or_pseudopart-lex-rule := partitive-lex-rule &
  [ SYNSEM [ LOCAL [ AGR #agr,
                     CAT [ HEAD noun & 
                                      [ MOD #mod,
                                        PRD #prd,
                                        TAM #tam, 
                                        CASE #case,
                                        VOICE #voice,
                                        VFORM #vform,
                                        INV #inv,
                                        KEYS [ KEY #key,
                                               ALTKEY quant_or_wh_rel,
                                               ALT2KEY #alt2key  ] ],
                           VAL [ SPR #spr & < [ OPT -,
                                         LOCAL local-min &
                                               [ AGR #agr,
                                                 CAT [ HEAD det & 
                                                            [ KEYS.KEY quant_or_wh_rel ], 
                                                       VAL.SUBJ < > ] ] ] > ] ],
                     CONT [ HOOK [ LTOP #ltop,
                                   INDEX #agr ],
			    RELS.LIST.FIRST #keyrel ] ],
             NON-LOCAL #nlocal,
             LKEYS.KEYREL #keyrel & noun-arg0-relation &
                          [ LBL #ltop,
                            PRED #pred,
                            ARG0 #agr ] ],
    DTR [ SYNSEM n_group-or-pseudopart_synsem &
                 [ LOCAL [ CAT [ HEAD partn & 
                                      [ MOD #mod,
                                        PRD #prd,
                                        TAM #tam, 
                                        CASE #case,
                                        VOICE #voice,
                                        VFORM #vform,
                                        INV #inv,
                                        KEYS [ KEY #key,
                                               ALTKEY part_q_rel,
                                               ALT2KEY #alt2key  ] ],
                                 VAL [ SPR < [ LOCAL.CAT.HEAD.KEYS.KEY part_q_rel ] >,
                                       COMPS < [ OPT + ] > ] ], 
                           CONT [ HOOK [ LTOP #ltop,
                                         INDEX #agr ],
                                  RELS <! [ PRED #pred ] !> ] ] ] ],
    ARG-ST #spr & < [ NON-LOCAL #nlocal ] >,
    C-CONT.RELS <! #keyrel !> ].


part_pron-lex-rule := partitive-lex-rule &
  [ SYNSEM [ LOCAL [ AGR #agr,
                     CAT [ HEAD #head,
                           VAL.SPR #spr ],
                     CONT.HOOK [ LTOP #ltop,
                                 INDEX #index ] ],
             LKEYS.KEYREL #keyrel & noun-arg0-relation &
                          [ PRED generic_entity_rel,
                            LBL #ltop,
                            ARG0 #index ] ],
    DTR [ SYNSEM basic-partitive-pron-synsem &
                 [ LOCAL [ AGR #agr,
                           CAT [ HEAD #head & partn,
                                 VAL [ SPR #spr,
                                       COMPS < [ OPT - ] > ] ], 
                           CONT [ HOOK [ LTOP #ltop,
                                         INDEX #index ] ] ] ] ],
    C-CONT.RELS <! #keyrel !> ].

norm_part_pron-lex-rule := part_pron-lex-rule &
  [ SYNSEM [ LOCAL.CONT.RELS <! #keyrel, #altkey !>,
             LKEYS [ KEYREL #keyrel,
                     ALTKEYREL #altkey ] ],
    DTR.SYNSEM [ LOCAL.CONT.RELS <! relation, #altkey !>,
                 LKEYS.ALTKEYREL #altkey ] ].

spcfied_part_pron-lex-rule := part_pron-lex-rule &
  [ SYNSEM [ LOCAL.CONT.RELS <! #keyrel !>,
             LKEYS.KEYREL #keyrel ],
    DTR.SYNSEM.LOCAL.CONT.RELS <! relation !> ].


; --- 6. LR types dealing with clitics
cliticization-lex-rule := basic-valence-alt-lex-rule &
  [ ALTS [ PERM #perm,
           PASS -,
           CAUS -,
           VFALT - ], 
    SYNSEM [ LOCAL [ AGR #agr,
                     CAT [ HEAD [ INV #inv,
                                  VFORM #vform,
                                  VOICE #voice,
                                  TAM #tam,
                                  PRD #prd,
                                  KEYS #keys,
                                  MOD #mod ],
                           VAL.SUBJ #subj ],
                     CONT #cont ],
             NON-LOCAL #nonloc,
             LKEYS.KEYREL #keyrel ],
    DTR [ INFLECTED -,
          ALTS.PERM #perm,
          SYNSEM [ LOCAL [ AGR #agr,
                           CAT [ HEAD verb & 
                                      [ AUX -,
                                        INV #inv,
                                        VFORM #vform,
                                        VOICE #voice,
                                        TAM #tam,
                                        PRD #prd,
                                        KEYS #keys,
                                        MOD #mod ],
                                 VAL.SUBJ #subj ],
                           CONT #cont ],
                   NON-LOCAL #nonloc,
                   LKEYS.KEYREL #keyrel ] ] ].


; --- 6.1 complement cliticization
comp-clt-lex-rule := cliticization-lex-rule &
  [ SYNSEM [ LOCAL.CAT [ HEAD.CLIT #case,
                         VAL [ COMPS #comps,
                               CLTS < #clt & affix-synsem & 
                                      [ OPT -,
                                        LOCAL.CAT.HEAD affix & [ CASE #case ] ] 
                                      . #clts > ] ] ] ,
    ARG-ST < #argst . < #clt > >,
    DTR [ SYNSEM.LOCAL.CAT.VAL [ COMPS < [ CLTCZD +,
				           NON-LOCAL.SLASH 0-dlist ]
                                         . #comps >,
                                 CLTS #clts ],
          ARG-ST #argst ] ].


; -- accusative complement cliticization lexical rules

; - for transitive verbs taking NPs (e.g. lo come, lo invierte (en bolsa), los amenaza con llorar, los pone 
; en el tren,...) and finite completive clauses and/or VPinf (e.g. lo quiere) or interrogative clauses 
; (e.g. lo sabe) and for impersonal transitive verbs 
; With ditransitive verbs, you can't cliticize only the DO (e.g. *lo di a María, *lo dije a Juan). 
; !!! indefinite DO can't be cliticized (e.g. ¿compraste flores? *Sí, las compré; *¿A quién lo viste?), 
; but I can't control this.
; !!! dislocated DOs require clitics, unless it's indefinite (e.g. esa película la ví hace tres años, 
; unos libros compré ayer)
acc_comp-clt-lex-rule := comp-clt-lex-rule & 
  [ SYNSEM [ LOCAL.CAT.VAL.CLTS < [ LOCAL [ CAT.HEAD.CASE acc_or_dat,
                                            CONT.HOOK.INDEX #affix ] ] > ],
    DTR.SYNSEM transitive_verb_synsem &
               [ LOCAL.CAT.VAL.COMPS < [ LOCAL np_acc_local & 
                                               [ CONT.HOOK.INDEX #affix ] ],... > ] ].

; - leísmo
;le_acc_comp-clt-lex-rule := comp-clt-lex-rule & 
;  [ SYNSEM.LOCAL.CAT.VAL.CLTS < [ LOCAL [ CAT.HEAD.CASE only_dat,
;                                          CONT.HOOK.INDEX #affix ] ] >,
;    DTR.SYNSEM v_trans_synsem &
;               [ LOCAL.CAT.VAL.COMPS < [ LOCAL np_acc_local & 
;                                               [ CONT.HOOK.INDEX #affix & [ SORT hum ] ] ],... > ] ].


; -- dative complement cliticization lexical rules
; !!! los clíticos dativos pueden tener valor locativo y reproducir complementos (con de) 
; de locuciones con este valor (se le acercó, se le puso al lado, se le sentó encima) y referirse 
; a sintagmas con para en oraciones impersonales con "ser/resultar + adjetivo" (le es fácil 
; conducir, le resulta divertido).

; - for ditransitive verbs (e.g. les compró caramelos, le prometió que iría/venir)
dat_comp-clt-lex-rule := comp-clt-lex-rule & 
  [ SYNSEM.LOCAL.CAT.VAL.CLTS < [ LOCAL [ CAT.HEAD.CASE dat,
                                          CONT.HOOK.INDEX #affix ] ] >,
    DTR.SYNSEM.LOCAL.CAT.VAL.COMPS < [ LOCAL dative_local &
                                             [ CONT.HOOK.INDEX #affix ] ],... > ].

; - laísmo (only with intrans verbs)
;la_dat_comp-clt-lex-rule := comp-clt-lex-rule & 
;  [ SYNSEM.LOCAL.CAT.VAL.CLTS < [ LOCAL [ CAT.HEAD.CASE acc,
;                                          CONT.HOOK.INDEX #affix ] ],... >,
;    DTR.SYNSEM.LOCAL.CAT.VAL.COMPS < [ LOCAL dative_local &
;                                             [ CONT.HOOK.INDEX #affix ] ] > ].


; -- multiple complement cliticization (including pronominal verbs) lexical rule
; for ditransitive verbs taking DO and IO (e.g. se los compró) and ditransitive verbs taking IO 
; and verbal complement (e.g. se lo prometió)
; order: - 2nd+1st (te me fuiste) / 1st/2nd+3rd (me/te lo dieron)  
;        - reflexive benefactive dative accusative
; no pueden coaparecer un clitico dativo de tercera persona y uno acusativo de primera o segunda persona
; (e.g. se le entregó, *me le entregaron)

mult_comp-clt-lex-rule := comp-clt-lex-rule & 
  [ SYNSEM.LOCAL.CAT.VAL.CLTS < [ LOCAL [ CAT.HEAD.CASE acc,
                                          CONT.HOOK.INDEX #affix ] ], 
                                [ LOCAL.CAT.HEAD.CASE rflx ] >,
    DTR.SYNSEM.LOCAL.CAT.VAL.COMPS < [ LOCAL np_acc_local & 
                                             [ CONT.HOOK.INDEX #affix ] ],... > ].

vpron_mult_comp-clt-lex-rule := comp-clt-lex-rule & 
  [ SYNSEM.LOCAL.CAT.VAL.CLTS < [ LOCAL [ CAT.HEAD.CASE dat,
                                          CONT.HOOK.INDEX #affix ] ], 
                                [ LOCAL.CAT.HEAD.CASE rflx ] >,
    DTR.SYNSEM.LOCAL.CAT.VAL.COMPS < [ LOCAL dative_local &
                                             [ CONT.HOOK.INDEX #affix ] ],... > ].


; --- 6.2. clitic doubling
; !!! when the canonic object, both direct and indirect, is a pronoun (except "usted" and "ello"), 
; clitic doubling is obligatory (e.g. *(me) ha visto a mí; (le) agradezco a usted; dedicaré a ello 
; el siguiente capítulo)

; - clitic-doubling the first element in the COMPS list 
; e.g. le ordenó al chico salir
1st-clt-doubl-lex-rule := cliticization-lex-rule &
  [ SYNSEM.LOCAL.CAT [ HEAD.CLIT #case,
                       VAL [ COMPS < [ OPT -,
                                       CLTCZD -,
				       LOCAL #local,
                                       NON-LOCAL #nonloc ]
                                     . #comps >,
                             CLTS < #clt & affix-synsem & 
                                      [ OPT -,
                                        LOCAL [ CAT.HEAD affix & [ CASE #case ] ] ] 
                                    . #clts > ] ],
    ARG-ST < #argst . < #clt > >,
    DTR [ SYNSEM.LOCAL.CAT.VAL [ COMPS < [ LOCAL #local,
                                           CLTCZD +,
				           NON-LOCAL #nonloc & [ SLASH 0-dlist ] ]
                                         . #comps >,
                                 CLTS #clts ],
          ARG-ST #argst ] ].

; -- clitic-doubling the second element in the COMPS list 
; e.g. le envió cartas a su padre
2nd-clt-doubl-lex-rule := cliticization-lex-rule &
  [ SYNSEM.LOCAL.CAT [ HEAD.CLIT #case,
                       VAL [ COMPS < #comp,
                                     [ OPT -,
                                       CLTCZD -,
				       LOCAL #local,
                                       NON-LOCAL #nonloc ] >,
                             CLTS < #clt & affix-synsem & 
                                    [ OPT -,
                                      LOCAL [ CAT.HEAD affix & [ CASE #case ],
                                              CONT.HOOK.INDEX #aff ] ] > ] ],
    ARG-ST < #argst . < #clt > >,
    DTR [ SYNSEM.LOCAL.CAT.VAL [ COMPS < #comp, 
                                         [ CLTCZD +,
				           LOCAL #local & [ CAT.HEAD.CASE #case,
                                                            CONT.HOOK.INDEX #aff ],
                                           NON-LOCAL #nonloc & [ SLASH 0-dlist ] ] >,
                                 CLTS < > ],
          ARG-ST #argst ] ].


; -- accusative clitic doubling lexical rule
; - for transitive verbs when the DO is a quantifier (e.g. lo sé todo, los conozco a todos) or 
; takes a numeral (e.g. los conozco a los tres), though we may also find examples like: la ayudo 
; a mi madre, lo sé que te sientes mal, therefore, I don't specify restrictions when it takes a 
; single complement
acc_1st-clt-doubl-lex-rule := 1st-clt-doubl-lex-rule & 
  [ SYNSEM.LOCAL.CAT.VAL.CLTS < [ LOCAL [ CAT.HEAD.CASE acc,
                                          CONT.HOOK.INDEX #aff ] ] >,
    DTR.SYNSEM transitive_verb_synsem &
               [ LOCAL.CAT.VAL.COMPS < [ LOCAL [ CONT.HOOK.INDEX #aff ] ],... > ] ].

; - leísmo
;le_acc_1st-clt-doubl-lex-rule := 1st-clt-doubl-lex-rule & 
;  [ SYNSEM.LOCAL.CAT.VAL.CLTS < [ LOCAL [ CAT.HEAD.CASE only_dat,
;                                          CONT.HOOK.INDEX #affix ] ] >,
;    DTR.SYNSEM v_trans_synsem &
;               [ LOCAL.CAT.VAL.COMPS < [ LOCAL np_acc_local & 
;                                               [ CONT.HOOK.INDEX #affix & [ SORT hum ] ] ],... > ] ].


; -- dative clitic doubling lexical rule
; - for ditrans verbs (e.g. les compró caramelos a los niños, le dijeron a Juan que viniera)
; !!! dative clitic doubling is always possible. With ditransitive verbs it's optional 
; (e.g. (le) dieron el premio al escritor, (le) dijeron a Juan que viniera), it's obligatory with 
; dativos experimentantes (*(le) gusta el cine a Juan), beneficiarios ((*le) preparó un brevaje al 
; enfermo, *(le) hice los deberes a los niños), poseedor inelienable (*(le) cortaron las uñas al 
; niño, *(le) le duele la pierna a Pedro). El clitico dativo de tercera persona puede perder la 
; marca de plural cuando está reduplicado (no le tiene miedo a las balas)
dat_1st-clt-doubl-lex-rule := 1st-clt-doubl-lex-rule & 
  [ SYNSEM.LOCAL.CAT.VAL.CLTS < [ LOCAL [ CAT.HEAD.CASE dat,
                                          CONT.HOOK.INDEX.PNG.GEN #gen ] ] >,
    DTR.SYNSEM [ LOCAL.CAT.VAL.COMPS < [ LOCAL dative_local & 
                                               [ CONT.HOOK.INDEX.PNG.GEN #gen ] ] > ] ].
;la_dat_1st-clt-doubl-lex-rule := 1st-clt-doubl-lex-rule & 
;  [ SYNSEM.LOCAL.CAT.VAL.CLTS < [ LOCAL [ CAT.HEAD.CASE acc,
;                                          CONT.HOOK.INDEX.PNG.GEN #gen ] ] >,
;    DTR.SYNSEM [ LOCAL.CAT.VAL.COMPS < [ LOCAL dative_local & 
;                                               [ CONT.HOOK.INDEX.PNG.GEN #gen ] ],... > ] ].

dat_2nd-clt-doubl-lex-rule := 2nd-clt-doubl-lex-rule & 
  [ SYNSEM.LOCAL.CAT.VAL.CLTS < [ LOCAL [ CAT.HEAD.CASE dat,
                                          CONT.HOOK.INDEX.PNG.GEN #gen ] ] >,
    DTR.SYNSEM [ LOCAL.CAT.VAL.COMPS < synsem, 
                                       [ LOCAL dative_local & 
                                               [ CONT.HOOK.INDEX.PNG.GEN #gen ] ] > ] ].

;la_dat_2nd-clt-doubl-lex-rule := 2nd-clt-doubl-lex-rule & 
;  [ SYNSEM.LOCAL.CAT.VAL.CLTS < [ LOCAL [ CAT.HEAD.CASE acc,
;                                          CONT.HOOK.INDEX.PNG.GEN #gen ] ] >,
;    DTR.SYNSEM [ LOCAL.CAT.VAL.COMPS < synsem, 
;                                       [ LOCAL dative_local & 
;                                               [ CONT.HOOK.INDEX.PNG.GEN #gen ] ] > ] ].


; -- c)- multiple clitic doubling lexical rule
; for ditransitive verbs taking DO and IO (e.g. se los compró al chico) & ditransitive verbs 
; taking IO and verbal complement (e.g. se lo prometió al chico)
mult_1st-clt-doubl-lex-rule := 1st-clt-doubl-lex-rule & 
  [ SYNSEM.LOCAL.CAT.VAL.CLTS < [ LOCAL [ CAT.HEAD.CASE acc,
                                          CONT.HOOK.INDEX #aff ] ], 
                                [ LOCAL.CAT.HEAD.CASE rflx ] >,
    DTR.SYNSEM.LOCAL.CAT.VAL.COMPS < [ LOCAL np_acc_local & 
                                             [ CONT.HOOK.INDEX #aff ] ],... > ].

vpron_mult_1st-clt-doubl-lex-rule := 1st-clt-doubl-lex-rule & 
  [ SYNSEM.LOCAL.CAT.VAL.CLTS < [ LOCAL [ CAT.HEAD.CASE rflx,
                                          CONT.HOOK.INDEX #affix ] ], 
                                [ LOCAL.CAT.HEAD.CASE rflx ] >,
    DTR.SYNSEM.LOCAL.CAT.VAL.COMPS < [ LOCAL dative_local &
                                             [ CONT.HOOK.INDEX #affix ] ],... > ].