;;; Hey, emacs(1), this is -*- Mode: TDL; Coding: utf-8; -*- got it?


n+p+q+n_sg_en := exhaustive_mtr &
[ INPUT [ INDEX #e0,
          RELS < [ PRED "~_n_", LBL #h4, ARG0 #x3 ],
                 [ PRED "~_p_", LBL #h4, ARG1 #x3, ARG2 #x5 ],
                 [ PRED "~_q_", ARG0 #x5, RSTR #h6 ],
                 [ PRED "~_n_", LBL #h7, ARG0 #x5 & [ NUM sg ] ],
                 [ PRED unknown_rel, LBL #h2, ARG0 #e0, ARG #x3 & x ],
                 [ ARG0 #x3, RSTR #h8 ] >,
          HCONS < qeq & [ HARG #h6, LARG #h7 ],
                  qeq & [ HARG #h8, LARG #h4 ] > ],
  OUTPUT.RELS < +copy+, +copy+, +copy+, +copy+ >,
  FLAGS.EQUAL < #x3 > ].


n+p+q+n_pl_en := exhaustive_mtr &
[ INPUT [ INDEX #e0,
          RELS < [ PRED "~_n_", LBL #h4, ARG0 #x3 ],
                 [ PRED "~_p_", LBL #h4, ARG1 #x3, ARG2 #x5 ],
                 [ PRED "~_q_", ARG0 #x5, RSTR #h6 ],
                 [ PRED "~_n_", LBL #h7, ARG0 #x5 & [ NUM pl ] ],
                 [ PRED unknown_rel, LBL #h2, ARG0 #e0, ARG #x3 & x ],
                 [ ARG0 #x3, RSTR #h8 ] >,
          HCONS < qeq & [ HARG #h6, LARG #h7 ],
                  qeq & [ HARG #h8, LARG #h4 ] > ],
  OUTPUT.RELS < +copy+, +copy+, +copy+, +copy+ >,
  FLAGS.EQUAL < #x3 > ].


nominalization*n_en := exhaustive_mtr &
[ INPUT [ INDEX #e0,
          RELS < [ PRED "~_v_", LBL #h11 ],
                 [ PRED "~_n_", LBL #h5, ARG0 #x3 & [ NUM sg ] ],
                 [ PRED unknown_rel, LBL #h2, ARG0 #e0, ARG #x3 & x ],
                 [ PRED compound_rel, ARG1 #x3, ARG2 #x8 ],
                 [ PRED nominalization_rel, LBL #h7, ARG0 #x8, ARG1 #h11 ],
                 [ ARG0 #x3, RSTR #h4 ],
                 [ ARG0 #x8, RSTR #h6 ] >,
          HCONS < qeq & [ HARG #h4, LARG #h5 ],
                  qeq & [ HARG #h6, LARG #h7 ] > ],
  OUTPUT.RELS < +copy+, +copy+ >,
  FLAGS.OPTIONAL +,
  FLAGS.EQUAL < #x3 > ].


n*nominalization_en := exhaustive_mtr &
[ INPUT [ INDEX #e0,
          RELS < [ PRED "~_n_", LBL #h5, ARG0 #x3 ],
                 [ PRED "~_v_", LBL #h11 ],
                 [ PRED unknown_rel, LBL #h2, ARG0 #e0, ARG #x8 & x ],
                 [ PRED compound_rel, ARG1 #x8, ARG2 #x3 ],
                 [ PRED nominalization_rel, LBL #h7, 
                   ARG0 #x8 & [ NUM sg ], ARG1 #h11 ],
                 [ ARG0 #x3, RSTR #h4 ],
                 [ ARG0 #x8, RSTR #h6 ] >,
          HCONS < qeq & [ HARG #h4, LARG #h5 ],
                  qeq & [ HARG #h6, LARG #h7 ] > ],
  OUTPUT.RELS < +copy+, +copy+ >,
  FLAGS.EQUAL < #x3 > ].


n*n_en := exhaustive_mtr &
[ INPUT [ INDEX #e0,
          RELS < [ PRED "~_n_", LBL #h7, ARG0 #x8 ],
                 [ PRED "~_n_", LBL #h5, ARG0 #x3 & [ NUM sg ] ],
                 [ PRED unknown_rel, LBL #h2, ARG0 #e0, ARG #x3 & x ],
                 [ PRED compound_rel, ARG1 #x3, ARG2 #x8 ],
                 [ ARG0 #x3, RSTR #h4 ],
                 [ ARG0 #x8, RSTR #h6 ] >,
          HCONS < qeq & [ HARG #h4, LARG #h5 ],
                  qeq & [ HARG #h6, LARG #h7 ] > ],
  OUTPUT.RELS < +copy+, +copy+ >,
  FLAGS.EQUAL < #x3 > ].


;;;
;;; _fix_me_
;;; work this out properly one day.                            (30-may-06; oe)
;;;
#|
n+poss+n_en := exhaustive_mtr &
[ INPUT [ INDEX #e0,
          RELS < [ PRED "~_n_", LBL #h7, ARG0 #x8 ],
                 [ PRED "~_n_", LBL #h5, ARG0 #x3 ],
                 [ PRED unknown_rel, LBL #h2, ARG0 #e0, ARG #x3 & x ],
                 [ PRED poss_rel, ARG1 #x3, ARG2 #x8 ],
                 [ ARG0 #x3, RSTR #h4 ],
                 [ ARG0 #x8, RSTR #h6 ] >,
          HCONS < qeq & [ HARG #h4, LARG #h5 ],
                  qeq & [ HARG #h6, LARG #h7 ] > ],
  OUTPUT.RELS < +copy+, +copy+ >,
  FLAGS.EQUAL < #x3 > ].
|#


adj+n_en := exhaustive_mtr &
[ INPUT [ INDEX #e0,
          RELS < [ PRED "~_a_", LBL #h5, ARG1 #x3 ],
                 [ PRED "~_n_", LBL #h5, ARG0 #x3 & [ NUM sg ] ],
                 [ PRED unknown_rel, LBL #h2, ARG0 #e0, ARG #x3 & x ],
                 [ ARG0 #x3, RSTR #h4 ] >,
          HCONS < qeq & [ HARG #h4, LARG #h5 ] > ],
  OUTPUT.RELS < +copy+, +copy+ >,
  FLAGS.EQUAL < #x3 > ].


nominalization_en := exhaustive_mtr &
[ INPUT [ INDEX #e0,
          RELS < [ PRED "~_v_", LBL #h8 ],
                 [ PRED unknown_rel, LBL #h2, ARG0 #e0, ARG #x3 & x ],
                 [ PRED nominalization_rel, LBL #h5, 
                   ARG0 #x3 & [ NUM sg ], ARG1 #h8 ],
                 [ ARG0 #x3, RSTR #h4 ] >,
          HCONS < qeq & [ HARG #h4, LARG #h5 ] > ],
  OUTPUT.RELS < +copy+ >,
  FLAGS.EQUAL < #x3 > ].


adjective_en := exhaustive_mtr &
[ INPUT [ INDEX #e0,
          RELS < [ PRED "~_a_", ARG1 #i4 ],
                 [ PRED unknown_rel, LBL #h2, ARG0 #e0, ARG #i4 ] >,
          HCONS < > ],
  OUTPUT.RELS < +copy+ > ].


;;;
;;; because PSP fragments are not marked for PROG et all, test this one before
;;; the present progressive participle (e.g. `managed' vs.`managing').
;;;
psp_participle_en := exhaustive_mtr &
[ INPUT [ INDEX #e0,
          RELS < [ PRED "~_v_", LBL #h5,
                   ARG0 #e3 & e & [ PROG -, TENSE untensed ] ],
                 [ PRED parg_d_rel, LBL #h5, ARG1 #e3 ],
                 [ PRED unknown_rel, LBL #h2, ARG0 #e0 ] >,
          HCONS < > ],
  OUTPUT.RELS < +copy+ >,
  FLAGS.EQUAL < #e3 > ].


prp_participle_en := exhaustive_mtr &
[ INPUT [ INDEX #e0,
          RELS < [ PRED "~_v_", LBL #h5,
                   ARG0 #e3 & e & [ PROG +, TENSE untensed ] ],
                 [ PRED unknown_rel, LBL #h2, ARG0 #e0 ] >,
          HCONS < > ],
  OUTPUT.RELS < +copy+ >,
  FLAGS.EQUAL < #e3 > ].


noun_en := exhaustive_mtr &
[ INPUT [ INDEX #e0,
          RELS < [ PRED "~_n_", LBL #h5, ARG0 #x3 & [ NUM sg ] ],
                 [ PRED unknown_rel, LBL #h2, ARG0 #e0, ARG #x3 & x ],
                 [ ARG0 #x3, RSTR #h4 ] >,
          HCONS < qeq & [ HARG #h4, LARG #h5 ] > ],
  OUTPUT.RELS < +copy+ >,
  FLAGS.EQUAL < #x3 > ].